Packages

stellar_sdk

0.14.0
0.23.0 0.22.0 0.21.2 0.21.1 0.21.0 0.20.0 0.19.0 0.18.1 0.18.0 0.17.1 0.17.0 0.16.1 0.16.0 0.15.1 0.15.0 0.14.0 0.13.1 0.13.0 0.12.0 0.11.8 0.11.7 0.11.6 0.11.5 0.11.4 0.11.3 0.11.2 0.11.1 0.11.0 0.10.2 0.10.1 0.10.0 0.9.3 0.9.2 0.9.1 0.9.0 0.8.1 0.8.0 0.7.1 0.7.0 0.6.0 0.5.0 0.4.0 0.3.0 0.2.0 0.1.0

Elixir SDK for the Stellar network.

HexDocs

Current section

Files

Jump to
Readme
45 Versions
4 Dependencies
Dependants
Files
Activity
stellar_sdk lib tx_build change_trust.ex
Raw

lib/tx_build/change_trust.ex 

defmodule Stellar.TxBuild.ChangeTrust do

  @moduledoc """

  Creates, updates, or deletes a trustline.

  """

  import Stellar.TxBuild.Validations,

    only: [validate_asset: 1, validate_optional_account: 1, validate_optional_amount: 1]



  alias Stellar.TxBuild.{Amount, Asset, OptionalAccount}

  alias StellarBase.XDR.{ChangeTrustAsset, OperationBody, OperationType, Operations.ChangeTrust}



  @behaviour Stellar.TxBuild.XDR



  @type asset_type :: :native | :alpha_num4 | :alpha_num12

  @type component :: {atom(), any()}

  @type validation :: {:ok, any()} | {:error, Keyword.t()}



  @type t :: %__MODULE__{

          asset: Asset.t(),

          amount: Amount.t(),

          source_account: OptionalAccount.t()

        }



  defstruct [:asset, :amount, :source_account]



  @impl true

  def new(args, opts \\ [])



  def new(args, _opts) when is_list(args) do

    asset = Keyword.get(args, :asset)

    amount = Keyword.get(args, :amount)

    source_account = Keyword.get(args, :source_account)



    with {:ok, asset} <- validate_asset({:asset, asset}),

         {:ok, amount} <- validate_optional_amount({:amount, amount}),

         {:ok, source_account} <- validate_optional_account({:source_account, source_account}) do

      %__MODULE__{

        asset: asset,

        amount: amount,

        source_account: source_account

      }

    end

  end



  def new(_args, _opts), do: {:error, :invalid_operation_attributes}



  @impl true

  def to_xdr(%__MODULE__{asset: asset, amount: amount}) do

    op_type = OperationType.new(:CHANGE_TRUST)

    asset_xdr = Asset.to_xdr(asset)

    amount_xdr = Amount.to_xdr(amount)



    asset_xdr.asset

    |> ChangeTrustAsset.new(asset_xdr.type)

    |> ChangeTrust.new(amount_xdr)

    |> OperationBody.new(op_type)

  end

end