phoenix

1.8.0-rc.4

1.8.9 1.8.8 1.8.7 1.8.6 1.8.5 1.8.4 1.8.3 1.8.2 1.8.1 1.8.0 1.8.0-rc.4 1.8.0-rc.3 1.8.0-rc.2 1.8.0-rc.1 1.8.0-rc.0 1.7.24 1.7.23 1.7.22 1.7.21 1.7.20 1.7.19 1.7.18 1.7.17 1.7.16 1.7.15 1.7.14 1.7.13 1.7.12 1.7.11 1.7.10 1.7.9 1.7.8 1.7.7 1.7.6 1.7.5 1.7.4 1.7.3 1.7.2 1.7.1 1.7.0 1.7.0-rc.3 1.7.0-rc.2 1.7.0-rc.1 1.7.0-rc.0 1.6.17 1.6.16 1.6.15 1.6.14 1.6.13 1.6.12 1.6.11 1.6.10 1.6.9 1.6.8 1.6.7 1.6.6 1.6.5 1.6.4 1.6.3 1.6.2 1.6.1 1.6.0 1.6.0-rc.1 1.6.0-rc.0 1.5.15 1.5.14 1.5.13 1.5.12 1.5.11 1.5.10 1.5.9 1.5.8 1.5.7 1.5.6 1.5.5 1.5.4 1.5.3 1.5.2 1.5.1 1.5.0 1.5.0-rc.0 1.4.18 1.4.17 1.4.16 1.4.15 1.4.14 1.4.13 1.4.12 1.4.11 1.4.10 1.4.9 1.4.8 1.4.7 1.4.6 1.4.5 1.4.4 1.4.3 1.4.2 1.4.1 1.4.0 1.4.0-rc.3 1.4.0-rc.2 1.4.0-rc.1 1.4.0-rc.0 1.3.5 1.3.4 1.3.3 1.3.2 1.3.1 1.3.0 1.3.0-rc.3 1.3.0-rc.2 1.3.0-rc.1 1.3.0-rc.0 1.2.5 1.2.4 1.2.3 1.2.2 1.2.1 1.2.0 1.2.0-rc.1 1.2.0-rc.0 1.1.9 1.1.8 1.1.7 1.1.6 1.1.5 1.1.4 1.1.3 1.1.2 1.1.1 1.1.0 1.0.6 1.0.5 1.0.4 1.0.3 1.0.2 1.0.1 1.0.0 0.17.1 0.17.0 0.16.1 0.16.0 0.15.0 0.14.0 0.13.1 0.13.0 0.12.0 0.11.0 0.10.0 0.9.0 0.8.0 0.7.2 0.7.1 0.7.0 0.6.2 0.6.1 0.6.0 0.5.0 0.4.1 0.4.0 0.3.1 0.3.0 0.2.11 0.2.10 0.2.9 0.2.8 0.2.7 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.2.0 0.1.0

Productive. Reliable. Fast. A productive web framework that does not compromise speed or maintainability.

Security advisory: This version has known vulnerabilities. View advisories

HexDocs

Current section

Files

Jump to

Readme 176 Versions 10 Dependencies Dependants 5 Advisories Files Activity

phoenix lib phoenix endpoint render_errors.ex

Raw

lib/phoenix/endpoint/render_errors.ex

defmodule Phoenix.Endpoint.RenderErrors do
  # This module is used to catch failures and render them using a view.
  #
  # This module is automatically used in `Phoenix.Endpoint` where it
  # overrides `call/2` to provide rendering. Once the error is
  # rendered, the error is reraised unless it is a NoRouteError.
  #
  # ## Options
  #
  #   * `:formats` - the format to use when none is available from the request
  #   * `:log` - the `t:Logger.level/0` or `false` to disable logging rendered errors
  #
  @moduledoc false

  import Plug.Conn

  require Phoenix.Endpoint
  require Logger

  alias Phoenix.Router.NoRouteError
  alias Phoenix.Controller

  @already_sent {:plug_conn, :sent}

  @doc false
  defmacro __using__(opts) do
    quote do
      @before_compile Phoenix.Endpoint.RenderErrors
      @phoenix_render_errors unquote(opts)
    end
  end

  @doc false
  defmacro __before_compile__(_) do
    quote location: :keep do
      defoverridable call: 2

      def call(conn, opts) do
        try do
          super(conn, opts)
        rescue
          e in Plug.Conn.WrapperError ->
            %{conn: conn, kind: kind, reason: reason, stack: stack} = e
            unquote(__MODULE__).__catch__(conn, kind, reason, stack, @phoenix_render_errors)
        catch
          kind, reason ->
            stack = __STACKTRACE__
            unquote(__MODULE__).__catch__(conn, kind, reason, stack, @phoenix_render_errors)
        end
      end
    end
  end

  @doc false
  def __catch__(%Plug.Conn{} = conn, kind, reason, stack, opts) do
    conn =
      receive do
        @already_sent ->
          send(self(), @already_sent)
          %{conn | state: :sent}
      after
        0 ->
          instrument_render_and_send(conn, kind, reason, stack, opts)
      end

    maybe_raise(kind, reason, stack)
    conn
  end

  defp instrument_render_and_send(conn, kind, reason, stack, opts) do
    level = Keyword.get(opts, :log, :debug)
    status = status(kind, reason)
    conn = error_conn(conn, kind, reason)
    start = System.monotonic_time()

    metadata = %{
      conn: conn,
      status: status,
      kind: kind,
      reason: reason,
      stacktrace: stack,
      log: level
    }

    try do
      render(conn, status, kind, reason, stack, opts)
    after
      duration = System.monotonic_time() - start
      :telemetry.execute([:phoenix, :error_rendered], %{duration: duration}, metadata)
    end
  end

  defp error_conn(_conn, :error, %NoRouteError{conn: conn}), do: conn
  defp error_conn(conn, _kind, _reason), do: conn

  defp maybe_raise(:error, %NoRouteError{}, _stack), do: :ok
  defp maybe_raise(kind, reason, stack), do: :erlang.raise(kind, reason, stack)

  ## Rendering

  @doc false
  def __debugger_banner__(_conn, _status, _kind, %NoRouteError{router: router}, _stack) do
    """
    <h3>Available routes</h3>
    <pre>#{Phoenix.Router.ConsoleFormatter.format(router)}</pre>
    """
  end

  def __debugger_banner__(_conn, _status, _kind, _reason, _stack), do: nil

  defp render(conn, status, kind, reason, stack, opts) do
    conn =
      conn
      |> maybe_fetch_query_params()
      |> fetch_view_format(opts)
      |> Plug.Conn.put_status(status)
      |> Controller.put_root_layout(opts[:root_layout] || false)
      |> Controller.put_layout(opts[:layout] || false)

    format = Controller.get_format(conn)
    reason = Exception.normalize(kind, reason, stack)
    template = "#{conn.status}.#{format}"
    assigns = %{kind: kind, reason: reason, stack: stack, status: conn.status, __changed__: nil}

    Controller.render(conn, template, assigns)
  end

  defp maybe_fetch_query_params(%Plug.Conn{} = conn) do
    fetch_query_params(conn)
  rescue
    Plug.Conn.InvalidQueryError ->
      case conn.params do
        %Plug.Conn.Unfetched{} -> %{conn | query_params: %{}, params: %{}}
        params -> %{conn | query_params: %{}, params: params}
      end
  end

  defp fetch_view_format(conn, opts) do
    # We ignore params["_format"] although we respect any already stored.
    view = opts[:view]
    formats = opts[:formats]
    accepts = opts[:accepts]

    cond do
      formats ->
        put_formats(conn, Enum.map(formats, fn {k, v} -> {Atom.to_string(k), v} end))

      view && accepts ->
        put_formats(conn, Enum.map(accepts, &{&1, view}))

      true ->
        raise ArgumentError,
              "expected :render_errors to have :formats or :view/:accepts, but got: #{inspect(opts)}"
    end
  end

  defp put_formats(conn, formats) do
    [{fallback_format, fallback_view} | _] = formats

    try do
      conn =
        case conn.private do
          %{phoenix_format: format} when is_binary(format) -> conn
          _ -> Controller.accepts(conn, Enum.map(formats, &elem(&1, 0)))
        end

      format = Phoenix.Controller.get_format(conn)

      case List.keyfind(formats, format, 0) do
        {_, view} ->
          Controller.put_view(conn, view)

        nil ->
          conn
          |> Controller.put_format(fallback_format)
          |> Controller.put_view(fallback_view)
      end
    rescue
      e in Phoenix.NotAcceptableError ->
        Logger.debug(
          "Could not render errors due to #{Exception.message(e)}. " <>
            "Errors will be rendered using the first accepted format #{inspect(fallback_format)} as fallback. " <>
            "Please customize the :formats option under the :render_errors configuration " <>
            "in your endpoint if you want to support other formats or choose another fallback"
        )

        conn
        |> Controller.put_format(fallback_format)
        |> Controller.put_view(fallback_view)
    end
  end

  defp status(:error, error), do: Plug.Exception.status(error)
  defp status(:throw, _throw), do: 500
  defp status(:exit, _exit), do: 500
end

Operator	Description	Example
name:	Match package name. Supports * wildcards and repo/package form	name:phx* or name:hexpm/phoenix
description:	Full-text search of package descriptions	description:auth
depends:	Packages depending on a given package. Supports repo:package form	depends:ecto or depends:hexpm:ecto
build_tool:	Filter by build tool	build_tool:mix
updated_after:	Packages updated after an ISO8601 datetime	updated_after:2025-01-01T00:00:00Z
extra:	Match custom metadata (key,value). Nested keys are separated by commas	extra:license,MIT