Packages

condukt

0.16.3
1.7.0 1.6.3 1.6.2 1.6.1 1.6.0 1.5.1 1.5.0 1.4.1 1.4.0 1.3.0 1.2.1 1.2.0 1.1.0 1.0.0 0.21.0 0.20.0 0.19.0 0.18.0 0.17.0 0.16.6 0.16.5 0.16.4 0.16.3 0.16.2 0.16.1 0.16.0 0.15.1 0.15.0 0.14.2 0.14.1 0.14.0 0.13.1 0.13.0 0.12.0 0.11.0 0.10.0 0.9.0 0.8.0 0.7.2 0.7.1 0.7.0 0.6.1 0.6.0 0.5.0

A framework for building AI agents in Elixir

HexDocs

Current section

Files

Jump to
Readme
44 Versions
10 Dependencies
Dependants
Files
Activity
condukt lib condukt session_store memory.ex
Raw

lib/condukt/session_store/memory.ex 

defmodule Condukt.SessionStore.Memory do

  @moduledoc """

  ETS-backed session store for restoring sessions within the current VM.

  """



  @behaviour Condukt.SessionStore



  alias Condukt.SessionStore.Snapshot



  @table __MODULE__



  @impl true

  def load(opts) do

    ensure_table!()



    case :ets.lookup(@table, key(opts)) do

      [{_, %Snapshot{} = snapshot}] -> {:ok, snapshot}

      [] -> :not_found

    end

  end



  @impl true

  def save(%Snapshot{} = snapshot, opts) do

    ensure_table!()

    true = :ets.insert(@table, {key(opts), snapshot})

    :ok

  end



  @impl true

  def clear(opts) do

    ensure_table!()

    true = :ets.delete(@table, key(opts))

    :ok

  end



  defp ensure_table! do

    case :ets.whereis(@table) do

      :undefined ->

        :global.trans({__MODULE__, :ensure_table}, &ensure_table_exists/0)



      tid ->

        tid

    end

  end



  defp ensure_table_exists do

    case :ets.whereis(@table) do

      :undefined -> :ets.new(@table, [:named_table, :public, :set, read_concurrency: true])

      tid -> tid

    end

  end



  defp key(opts) do

    Keyword.get_lazy(opts, :key, fn ->

      {

        Keyword.get(opts, :agent_module),

        Keyword.get(opts, :cwd)

      }

    end)

  end

end