Packages

want

1.17.0
2.0.0 1.22.0 1.21.1 1.21.0 1.20.0 1.19.0 1.18.0 1.17.1 1.17.0 1.16.0 1.15.6 1.15.5 1.15.4 1.15.3 1.15.2 1.15.1 1.15.0 1.14.4 1.14.3 1.14.0 1.13.1 1.13.0 1.12.0 1.11.0 1.10.1 1.10.0 1.9.0 1.8.1 1.8.0 1.7.0 1.6.0 1.5.0 1.4.0 1.3.1 1.3.0 1.2.0 1.1.1 1.1.0 0.4.0

Type conversion library for Erlang and Elixir.

HexDocs

Current section

Files

Jump to
Readme
39 Versions
0 Dependencies
Dependants
Files
Activity
want src want.erl
Raw

src/want.erl 

-module( want ).

-author( "Warren Kenny <warren.kenny@gmail.com>" ).



-export( [atom/1, atom/2, boolean/1, string/1, binary/1, integer/1, float/1] ).



%%

%%  @doc Convert the given value to an atom

%%

-spec atom( any() ) -> atom().

atom( V ) when is_atom( V )      -> V;

atom( V ) when is_binary( V )    -> binary_to_atom( V, utf8 );

atom( V ) when is_list( V )      -> list_to_atom( V );

atom( V ) when is_integer( V )   -> want:atom( integer_to_list( V ) );

atom( V ) when is_float( V )     -> want:atom( float_to_list( V ) ).



%%

%%  @doc Convert a float to an atom with the given precision

%%

-spec atom( float(), integer() ) -> atom().

atom( V, D ) when is_float( V )  -> want:atom( float_to_list( V, [{ decimals, D }] ) ).



%%

%%	@doc Convert the given value to a binary

%%

-spec binary( any() ) -> binary().

binary( V ) when is_binary( V ) 	-> V;

binary( V ) when is_atom( V )     -> atom_to_binary( V, utf8 );

binary( V ) when is_float( V )		-> float_to_binary( V );

binary( V ) when is_integer( V )	-> integer_to_binary( V );

binary( V ) when is_list( V )		  -> list_to_binary( V );

binary( V )							          -> term_to_binary( V ).



%%

%%	@doc Convert the given value to a string

%%

-spec string( any() ) -> string().

string( true )							      -> "true";

string( false )							      -> "false";

string( V ) when is_atom( V )			-> atom_to_list( V );

string( V ) when is_integer( V )	-> integer_to_list( V );

string( V ) when is_float( V ) 		-> float_to_list( V ); 

string( V ) when is_binary( V )		-> binary_to_list( V );

string( V ) when is_list( V )		  -> V.



%%

%%	@doc Convert the given value to a boolean

%%

-spec boolean( any() ) -> boolean().

boolean( true )							      -> true;

boolean( false )						      -> false;

boolean( 1 )                      -> true;

boolean( 0 )                      -> false;

boolean( <<"true">> )					    -> true;

boolean( <<"false">> )					  -> false;

boolean( "true" )						      -> true;

boolean( "false" )						    -> false.



%%

%%  @doc Convert the given value to an integer

%%

-spec integer( any() ) -> integer().

integer( V ) when is_integer( V ) -> V;

integer( V ) when is_float( V )	  -> list_to_integer( float_to_list( V, [{ decimals, 0 } ] ) );

integer( true )                   -> 1;

integer( false )                  -> 0;

integer( V ) when is_atom( V )    -> integer( atom_to_binary( V, unicode ) );

integer( V ) when is_binary( V )  -> binary_to_integer( V );

integer( V ) when is_list( V )    -> list_to_integer( V ).



%%

%%  @doc Convert the given value to an float

%%

-spec float( any() ) -> float().

float( V ) when is_float( V )     -> V;

float( V ) when is_integer( V )   -> erlang:float( V );

float( true )                     -> 1.0;

float( false )                    -> 0.0;

float( V ) when is_atom( V )      -> erlang:float( integer( V ) );

float( V ) when is_binary( V )    -> binary_to_float( V );

float( V ) when is_list( V )      -> list_to_float( V ).