Packages

ua_inspector

1.1.0
3.12.0 3.11.0 3.10.0 3.9.0 3.8.0 3.7.0 3.6.0 3.5.0 3.4.0 3.3.1 3.3.0 3.2.1 3.2.0 3.1.1 3.1.0 3.0.1 3.0.0 2.2.0 2.1.0 2.0.0 1.2.0 1.1.0 1.0.0 0.20.0 0.19.2 0.19.1 0.19.0 0.18.0 0.17.0 0.16.1 0.16.0 0.15.1 0.15.0 0.14.0 0.13.0 0.12.0 0.11.1 0.11.0 0.10.0 0.9.0 0.8.0 0.7.0 0.6.0

User agent parser library

HexDocs

Current section

Files

Jump to
Readme
43 Versions
2 Dependencies
4 Dependants
Files
Activity
ua_inspector lib ua_inspector parser os.ex
Raw

lib/ua_inspector/parser/os.ex 

defmodule UAInspector.Parser.OS do

  @moduledoc false



  alias UAInspector.Database.OSs

  alias UAInspector.Result

  alias UAInspector.Util



  @behaviour UAInspector.Parser



  @platforms [

    {"ARM", Util.build_regex("arm")},

    {"x64", Util.build_regex("WOW64|x64|win64|amd64|x86_64")},

    {"x86", Util.build_regex("i[0-9]86|i86pc")}

  ]



  def parse(ua), do: parse(ua, OSs.list())



  defp parse(_, []), do: :unknown



  defp parse(ua, [{_index, %{regex: regex} = entry} | database]) do

    if Regex.match?(regex, ua) do

      %Result.OS{

        name: resolve_name(ua, entry),

        platform: resolve_platform(ua),

        version: resolve_version(ua, entry)

      }

    else

      parse(ua, database)

    end

  end



  defp resolve_name(ua, %{name: name, regex: regex}) do

    captures = Regex.run(regex, ua)



    name

    |> Util.uncapture(captures)

    |> Util.sanitize_name()

    |> String.downcase()

    |> Util.OS.proper_case()

    |> Util.maybe_unknown()

  end



  defp resolve_version(ua, %{regex: regex, version: version}) do

    captures = Regex.run(regex, ua)



    version

    |> Util.uncapture(captures)

    |> Util.sanitize_version()

    |> Util.maybe_unknown()

  end



  defp resolve_platform(ua), do: resolve_platform(ua, @platforms)



  defp resolve_platform(_, []), do: :unknown



  defp resolve_platform(ua, [{id, regex} | platforms]) do

    if Regex.match?(regex, ua) do

      id

    else

      resolve_platform(ua, platforms)

    end

  end

end