Packages

tortoise

0.8.0
0.10.0 0.9.9 0.9.8 0.9.6 0.9.5 0.9.4 0.9.3 0.9.2 0.9.1 0.9.0 0.8.3 0.8.2 0.8.1 0.8.0 0.7.0 0.6.0 0.5.1 0.5.0 0.4.3 0.4.2 0.4.1 0.4.0 0.3.0 0.2.2 0.2.1 0.2.0 0.1.0

A MQTT client for Elixir.

HexDocs

Current section

Files

Jump to
Readme
27 Versions
2 Dependencies
Dependants
Files
Activity
tortoise lib tortoise connection backoff.ex
Raw

lib/tortoise/connection/backoff.ex 

defmodule Tortoise.Connection.Backoff do

  @moduledoc false



  defstruct min_interval: 100, max_interval: 30_000, value: nil

  alias __MODULE__, as: State



  @doc """

  Create an opaque data structure that describe a incremental

  back-off.

  """

  def new(opts) do

    min_interval = Keyword.get(opts, :min_interval, 100)

    max_interval = Keyword.get(opts, :max_interval, 30_000)



    %State{min_interval: min_interval, max_interval: max_interval}

  end



  def next(%State{value: nil} = state) do

    current = state.min_interval

    {current, %State{state | value: current}}

  end



  def next(%State{max_interval: same, value: same} = state) do

    current = state.min_interval

    {current, %State{state | value: current}}

  end



  def next(%State{value: value} = state) do

    current = min(value * 2, state.max_interval)

    {current, %State{state | value: current}}

  end



  def reset(%State{} = state) do

    %State{state | value: nil}

  end

end