Packages

toolshed

0.4.2
0.5.0 0.4.2 0.4.1 0.4.0 0.3.2 0.3.1 0.3.0 0.2.26 0.2.25 0.2.24 0.2.23 0.2.22 0.2.21 0.2.20 0.2.19 0.2.18 0.2.17 0.2.16 0.2.15 0.2.14 0.2.13 0.2.12 0.2.11 0.2.10 0.2.9 0.2.8 0.2.7 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.2.0 0.1.0

Use Toolshed for more IEx helpers

HexDocs

Current section

Files

Jump to
Readme
35 Versions
1 Dependency
Dependants
Files
Activity
toolshed lib_src core lsof.ex
Raw

lib_src/core/lsof.ex 

# SPDX-FileCopyrightText: 2019 Frank Hunleth

#

# SPDX-License-Identifier: Apache-2.0

#

defmodule Toolshed.Core.Lsof do

  @doc """

  List out open files by process



  This is an simple version of lsof that works on Linux and

  Nerves. While running the normal version of lsof provides

  more information, this can be convenient when lsof isn't

  easily available or can't be run due to `:emfile` errors

  from starting port processes due to too many files being open..

  """

  @spec lsof() :: :ok

  def lsof() do

    path_ls("/proc")

    |> Enum.filter(&File.dir?/1)

    |> Enum.each(&lsof_process/1)

  end



  defp lsof_process(path) do

    with {:ok, cmdline} <- File.read(Path.join(path, "cmdline")),

         [cmd | _args] <- String.split(cmdline, <<0>>) do

      path_ls(Path.join(path, "fd"))

      |> Enum.each(fn fd_path -> lsof_fd(fd_path, cmd) end)

    end

  end



  defp lsof_fd(fd_path, cmd) do

    case File.read_link(fd_path) do

      {:ok, where} ->

        IO.puts("#{where}\t\t\t#{cmd}")



      _other ->

        :ok

    end

  end



  defp path_ls(path) do

    case File.ls(path) do

      {:ok, names} ->

        Enum.map(names, fn name -> Path.join(path, name) end)



      _other ->

        []

    end

  end

end