Packages

toolshed

0.3.1
0.5.0 0.4.2 0.4.1 0.4.0 0.3.2 0.3.1 0.3.0 0.2.26 0.2.25 0.2.24 0.2.23 0.2.22 0.2.21 0.2.20 0.2.19 0.2.18 0.2.17 0.2.16 0.2.15 0.2.14 0.2.13 0.2.12 0.2.11 0.2.10 0.2.9 0.2.8 0.2.7 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.2.0 0.1.0

Use Toolshed for more IEx helpers

HexDocs

Current section

Files

Jump to
Readme
35 Versions
1 Dependency
Dependants
Files
Activity
toolshed lib_src core tree.ex
Raw

lib_src/core/tree.ex 

defmodule Toolshed.Core.Tree do

  @doc """

  Print out directories and files in tree form.

  """

  @spec tree(Path.t()) :: :"do not show this result in output"

  def tree(path \\ ".") do

    IO.puts(path)



    case file_info(path, path) do

      {:directory, _} ->

        do_tree("", path, files(path))



      _ ->

        :ok

    end



    IEx.dont_display_result()

  end



  defp do_tree(_prefix, _dir, []), do: :ok



  defp do_tree(prefix, dir, [{:directory, filename} | rest]) do

    puts_tree_branch(prefix, filename, rest)



    path = Path.join(dir, filename)

    do_tree([prefix, tree_trunk(rest)], path, files(path))

    do_tree(prefix, dir, rest)

  end



  defp do_tree(prefix, dir, [{_type, filename} | rest]) do

    puts_tree_branch(prefix, filename, rest)

    do_tree(prefix, dir, rest)

  end



  defp puts_tree_branch(prefix, filename, rest) do

    IO.puts([prefix, tree_branch(rest), filename])

  end



  defp tree_branch([]), do: "└── "

  defp tree_branch(_), do: "├── "



  defp tree_trunk([]), do: "    "

  defp tree_trunk(_), do: "│   "



  defp files(dir) do

    File.ls!(dir)

    |> Enum.map(&file_info(Path.join(dir, &1), &1))

  end



  defp file_info(path, name) do

    stat = File.lstat!(path)

    {stat.type, name}

  end

end