Packages

tigerbeetlex

0.16.47
0.16.78 0.16.77 0.16.76 0.16.75 0.16.73 0.16.72 0.16.70 0.16.69 0.16.68 0.16.67 0.16.66 0.16.65 0.16.64 0.16.63 0.16.62 0.16.61 0.16.60 0.16.59 0.16.58 0.16.57 0.16.56 0.16.55 0.16.54 0.16.53 0.16.52 0.16.51 0.16.50 0.16.48 0.16.47 0.16.46 0.16.45 0.16.44 0.16.43 0.16.42 0.16.41

Elixir client for TigerBeetle, the financial transactions database.

HexDocs

Current section

Files

Jump to
Readme
35 Versions
3 Dependencies
Dependants
Files
Activity
tigerbeetlex lib tigerbeetlex id server.ex
Raw

lib/tigerbeetlex/id/server.ex 

defmodule TigerBeetlex.ID.Server do

  @moduledoc false

  use Agent



  def start_link(_opts) do

    initial_time_ms = 0

    <<initial_random::unsigned-little-integer-size(80)>> = :rand.bytes(10)

    Agent.start_link(fn -> {initial_time_ms, initial_random} end, name: __MODULE__)

  end



  def generate_id do

    Agent.get_and_update(__MODULE__, &generate_and_update_state/1)

  end



  defp generate_and_update_state({last_time_ms, last_random} = _state) do

    current_time_ms = System.system_time(:millisecond)



    {time_ms, random} =

      if current_time_ms <= last_time_ms do

        incremented_random = check_overflow!(last_random + 1)

        {last_time_ms, incremented_random}

      else

        <<new_random::unsigned-little-integer-size(80)>> = :rand.bytes(10)

        {current_time_ms, new_random}

      end



    generated_id = <<random::unsigned-little-integer-size(80), time_ms::unsigned-little-integer-size(48)>>



    {generated_id, {time_ms, random}}

  end



  defp check_overflow!(n) do

    if <<n::unsigned-little-integer-size(80)>> == <<0::80>> do

      raise "Overflow in TigerBeetlex.ID.Server"

    else

      n

    end

  end

end