Packages

tesla

0.7.0
1.20.0 1.18.3 1.18.2 1.18.1 1.18.0 1.17.0 1.16.0 1.15.3 1.15.2 1.15.1 1.15.0 1.14.3 1.14.2 1.14.1 1.14.0 1.13.2 1.13.1 1.13.0 1.12.3 1.12.2 1.12.1 1.12.0 1.11.2 1.11.1 1.11.0 1.10.3 1.10.2 1.10.1 1.10.0 1.9.0 1.8.1 retired 1.8.0 1.7.0 1.6.1 1.6.0 1.5.1 1.5.0 1.4.4 1.4.3 1.4.2 1.4.1 1.4.0 1.3.3 1.3.2 1.3.1 1.3.0 1.2.1 1.2.0 1.1.0 1.0.0 1.0.0-beta.1 0.10.0 0.9.0 0.8.0 0.7.2 0.7.1 0.7.0 0.6.0 0.5.2 0.5.1 0.5.0 0.3.6 0.3.5 0.3.4 0.3.3 0.3.2 0.3.1 0.2.2 0.2.1 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0

HTTP client library, with support for middleware and multiple adapters.

Security advisory: This version has known vulnerabilities. View advisories
HexDocs

Current section

Files

Jump to
Readme
75 Versions
5 Dependencies
512 Dependants
5 Advisories
Files
Activity
tesla lib tesla middleware json.ex
Raw

lib/tesla/middleware/json.ex 

defmodule Tesla.Middleware.JSON do

  # NOTE: text/javascript added to support Facebook Graph API.

  #       see https://github.com/teamon/tesla/pull/13

  @default_content_types ["application/json", "text/javascript"]

  @default_engine Poison



  @doc """

  Encode and decode response body as JSON



  Available options:

  - `:decode` - decoding function

  - `:encode` - encoding function

  - `:engine` - encode/decode engine, e.g `Poison` or `JSX`  (defaults to Poison)

  - `:engine_opts` - optional engine options

  - `:decode_content_types` - list of additional decodable content-types

  """

  def call(env, next, opts) do

    opts = opts || []



    env

    |> encode(opts)

    |> Tesla.run(next)

    |> decode(opts)

  end



  def encode(env, opts) do

    if encodable?(env) do

      env

      |> Map.update!(:body, &encode_body(&1, opts))

      |> Tesla.Middleware.Headers.call([], %{"content-type" => "application/json"})

    else

      env

    end

  end



  defp encode_body(%Stream{} = body, opts),             do: encode_stream(body, opts)

  defp encode_body(body, opts) when is_function(body),  do: encode_stream(body, opts)

  defp encode_body(body, opts), do: process(body, :encode, opts)



  defp encode_stream(body, opts) do

    Stream.map body, fn item -> encode_body(item, opts) <> "\n" end

  end



  def encodable?(env), do: env.body != nil



  def decode(env, opts) do

    if decodable?(env, opts) do

      Map.update!(env, :body, &process(&1, :decode, opts))

    else

      env

    end

  end



  def decodable?(env, opts), do: decodable_body?(env) && decodable_content_type?(env, opts)



  def decodable_body?(env) do

    (is_binary(env.body)  && env.body != "") ||

    (is_list(env.body)    && env.body != [])

  end



  def decodable_content_type?(env, opts) do

    case env.headers["content-type"] do

      nil           -> false

      content_type  -> Enum.any?(content_types(opts), &String.starts_with?(content_type, &1))

    end

  end



  def content_types(opts), do: @default_content_types ++ Keyword.get(opts, :decode_content_types, [])



  defp process(data, op, opts) do

    with {:ok, value} <- do_process(data, op, opts) do

      value

    else

      {:error, reason} -> raise %Tesla.Error{message: "JSON #{op} error: #{inspect reason}", reason: reason}

    end

  end



  defp do_process(data, op, opts) do

    if fun = opts[op] do # :encode/:decode

      fun.(data)

    else

      engine  = Keyword.get(opts, :engine, @default_engine)

      opts    = Keyword.get(opts, :engine_opts, [])



      apply(engine, op, [data, opts])

    end

  end

end







defmodule Tesla.Middleware.DecodeJson do

  def call(env, next, opts) do

    opts = opts || []



    env

    |> Tesla.run(next)

    |> Tesla.Middleware.JSON.decode(opts)

  end

end



defmodule Tesla.Middleware.EncodeJson do

  def call(env, next, opts) do

    opts = opts || []



    env

    |> Tesla.Middleware.JSON.encode(opts)

    |> Tesla.run(next)

  end

end