Packages

styler

1.11.0
1.11.0 1.10.1 1.10.0 1.9.1 1.9.0 1.8.0 1.7.0 1.6.0 1.5.1 1.5.0 1.4.2 1.4.1 1.4.0 1.3.3 1.3.2 1.3.1 1.3.0 1.2.1 1.2.0 1.1.2 1.1.1 1.1.0 1.0.0 1.0.0-rc.2 1.0.0-rc.1 1.0.0-rc.0 1.0.0-alpha.0 0.11.9 0.11.8 0.11.7 0.11.6 0.11.5 0.11.4 0.11.3 0.11.2 0.11.1 0.11.0 0.10.5 0.10.4 retired 0.10.3 0.10.2 0.10.1 0.10.0 0.9.7 0.9.6 0.9.5 0.9.4 0.9.3 0.9.2 retired 0.9.1 retired 0.9.0 0.8.5 0.8.4 0.8.3 0.8.2 0.8.1 0.8.0 0.7.14 0.7.13 0.7.12 0.7.11 0.7.10 0.7.9 0.7.8 0.7.7 0.7.6 0.7.5 0.7.4 0.7.3 0.7.2 0.7.1 0.7.0 0.6.1 0.6.0 0.5.2 0.5.1 0.5.0 0.4.1 0.4.0 0.3.1 0.3.0 0.2.0 0.1.1 0.1.0

A code-style enforcer that will just FIFY instead of complaining

HexDocs

Current section

Files

Jump to
Readme
84 Versions
0 Dependencies
Dependants
Files
Activity
styler lib style inline_attrs.ex
Raw

lib/style/inline_attrs.ex 

# Copyright 2025 Adobe. All rights reserved.

# This file is licensed to you under the Apache License, Version 2.0 (the "License");

# you may not use this file except in compliance with the License. You may obtain a copy

# of the License at http://www.apache.org/licenses/LICENSE-2.0



# Unless required by applicable law or agreed to in writing, software distributed under

# the License is distributed on an "AS IS" BASIS, WITHOUT WARRANTIES OR REPRESENTATIONS

# OF ANY KIND, either express or implied. See the License for the specific language

# governing permissions and limitations under the License.



defmodule Styler.Style.InlineAttrs do

  @moduledoc false

  alias Styler.Style

  alias Styler.Zipper



  def run(zipper, ctx) do

    if defstructz = Zipper.find(zipper, &match?({:defmodule, _, _}, &1)) do

      body_zipper = defstructz |> Zipper.down() |> Zipper.right() |> Zipper.down() |> Zipper.down() |> Zipper.right()



      {literal_attrs, others} =

        body_zipper

        |> Zipper.children()

        |> Enum.split_with(fn

          {:@, _, [{_name, _, [{:to_timeout, _, values}]}]} -> quoted_literal?(values)

          {:@, _, [{name, _, values}]} -> name not in ~w(doc impl moduledoc)a and quoted_literal?(values)

          _ -> false

        end)



      {_, hits} =

        Macro.prewalk(others, %{}, fn

          {:@, _, [{name, _, _}]} = ast, acc ->

            def = Enum.find(literal_attrs, &match?({:@, _, [{^name, _, _}]}, &1))

            val = def && {def, ast}

            {ast, Map.update(acc, name, val, fn _ -> false end)}



          ast, acc ->

            {ast, acc}

        end)



      zipper =

        hits

        |> Enum.filter(fn {_, v} -> v end)

        |> Enum.reduce(body_zipper, fn {_, {def, ast}}, zipper ->

          {_, _, [{_, _, [value]}]} = def

          replacement = Style.set_line(value, Style.meta(ast)[:line])



          zipper

          |> Zipper.find(&match?(^def, &1))

          |> Zipper.remove()

          |> Zipper.find(&match?(^ast, &1))

          |> Zipper.replace(replacement)

          |> Zipper.top()

        end)



      {:halt, zipper, ctx}

    else

      {:halt, zipper, ctx}

    end

  end



  # Can't rely on `Macro.quoted_literal?` up front because we wrapped our literals :/

  # This function is not complete, but it's good enough for the needs here.

  defp quoted_literal?(value) when is_list(value) or is_map(value) do

    Enum.all?(value, fn

      {k, v} -> quoted_literal?(k) and quoted_literal?(v)

      value -> quoted_literal?(value)

    end)

  end



  defp quoted_literal?({:__block__, _, [value]}), do: quoted_literal?(value)

  defp quoted_literal?(value), do: Macro.quoted_literal?(value)

end