Packages

stellar_base

0.2.1
0.17.0 0.16.0 0.15.1 0.15.0 0.14.0 0.13.2 0.13.1 0.13.0 0.12.0 0.11.1 0.11.0 0.10.2 0.10.1 0.10.0 0.9.1 0.9.0 0.8.11 0.8.10 0.8.9 0.8.8 0.8.7 0.8.6 0.8.5 0.8.4 0.8.3 0.8.2 0.8.1 0.8.0 0.7.0 0.6.1 0.6.0 0.5.0 0.4.0 0.3.0 0.2.3 0.2.2 0.2.1 0.2.0 0.1.3 0.1.2 0.1.1 0.1.0

Low-level elixir library to read, write, hash, and sign XDR primitive constructs used in the Stellar network.

HexDocs

Current section

Files

Jump to
Readme
42 Versions
2 Dependencies
Dependants
Files
Activity
stellar_base lib xdr keys signer_key.ex
Raw

lib/xdr/keys/signer_key.ex 

defmodule StellarBase.XDR.SignerKey do

  @moduledoc """

  Representation of Stellar `SignerKey` type.

  """

  alias StellarBase.XDR.{UInt256, SignerKeyType}



  @behaviour XDR.Declaration



  @arms [

    SIGNER_KEY_TYPE_ED25519: UInt256,

    SIGNER_KEY_TYPE_PRE_AUTH_TX: UInt256,

    SIGNER_KEY_TYPE_HASH_X: UInt256

  ]



  @type t :: %__MODULE__{signer_key: UInt256.t(), type: SignerKeyType.t()}



  defstruct [:signer_key, :type]



  @spec new(signer_key :: UInt256.t(), type :: SignerKeyType.t()) :: t()

  def new(%UInt256{} = signer_key, %SignerKeyType{} = type),

    do: %__MODULE__{signer_key: signer_key, type: type}



  @impl true

  def encode_xdr(%__MODULE__{signer_key: signer_key, type: type}) do

    type

    |> XDR.Union.new(@arms, signer_key)

    |> XDR.Union.encode_xdr()

  end



  @impl true

  def encode_xdr!(%__MODULE__{signer_key: signer_key, type: type}) do

    type

    |> XDR.Union.new(@arms, signer_key)

    |> XDR.Union.encode_xdr!()

  end



  @impl true

  def decode_xdr(bytes, spec \\ union_spec())



  def decode_xdr(bytes, spec) do

    case XDR.Union.decode_xdr(bytes, spec) do

      {:ok, {{type, key}, rest}} -> {:ok, {new(key, type), rest}}

      error -> error

    end

  end



  @impl true

  def decode_xdr!(bytes, spec \\ union_spec())



  def decode_xdr!(bytes, spec) do

    {{type, key}, rest} = XDR.Union.decode_xdr!(bytes, spec)

    {new(key, type), rest}

  end



  @spec union_spec() :: XDR.Union.t()

  defp union_spec do

    nil

    |> SignerKeyType.new()

    |> XDR.Union.new(@arms)

  end

end