Packages

skogsra

2.2.0
2.5.3 2.5.2 2.5.1 2.5.0 2.4.2 2.4.1 2.4.0 2.3.3 2.3.2 2.3.1 2.3.0 2.2.3 2.2.2 2.2.1 2.2.0 2.1.1 2.1.0 2.0.4 2.0.3 2.0.2 2.0.1 2.0.0 1.3.2 1.3.1 1.3.0 1.2.1 1.2.0 1.1.1 1.1.0 1.0.4 1.0.3 1.0.2 1.0.1 1.0.0 0.2.2 0.2.1 0.2.0 0.1.2 0.1.1 0.1.0

Manages OS environment variables and application configuration options with ease

HexDocs

Current section

Files

Jump to
Readme
40 Versions
2 Dependencies
10 Dependants
Files
Activity
skogsra lib skogsra app.ex
Raw

lib/skogsra/app.ex 

defmodule Skogsra.App do

  @moduledoc """

  This module defines the functions to get variables from the application

  configuration.

  """

  use Skogsra.Binding



  alias Skogsra.Env



  ##########

  # Callback



  @impl Skogsra.Binding

  def get_env(env, config)



  def get_env(%Env{} = env, _config) do

    value = do_get_env(env)



    {:ok, value}

  end



  #########

  # Helpers



  @spec do_get_env(Env.t()) :: term()

  defp do_get_env(env)



  defp do_get_env(%Env{namespace: nil, keys: [key | keys]} = env) do

    do_get_env(%Env{env | namespace: key, keys: keys})

  end



  defp do_get_env(%Env{} = env) do

    application_module()

    |> apply(:get_env, [env.app_name, env.namespace])

    |> lookup(env.keys)

  end



  @spec lookup(term(), Env.keys()) :: nil | term()

  defp lookup(value, keys)



  defp lookup(value, []) do

    value

  end



  defp lookup(value, [key | keys]) when is_list(value) do

    value

    |> Keyword.get(key)

    |> lookup(keys)

  end



  defp lookup(_, _) do

    nil

  end



  @spec application_module() :: module()

  defp application_module do

    Application.get_env(:skogsra, :application_module, Application)

  end

end