Packages

rocksdb

1.3.1
3.1.1 3.1.0 3.0.0 2.6.2 2.6.1 retired 2.6.0 retired 2.5.0 2.4.1 2.4.0 2.3.0 2.2.0 2.1.0 2.0.0 1.9.0 1.8.0 1.7.0 1.6.0 1.5.1 1.5.0 1.4.0 1.3.2 1.3.1 1.3.0 1.2.0 1.1.1 1.1.0 1.0.0 0.26.2 0.26.1 0.26.0 0.25.0 0.24.0 0.23.3 0.23.2 0.23.1 0.23.0 0.22.0 0.21.0 0.20.1 0.20.0 0.19.0 0.18.0 0.17.0 0.16.0 0.15.0 0.14.0 0.13.1 0.13.0 0.12.0 0.11.0 0.10.0 0.9.1 0.9.0 0.8.2 0.8.1 0.8.0 0.7.1 0.7.0 0.6.4 0.6.3 0.6.2 0.6.1 0.6.0

RocksDB for Erlang

HexDocs

Current section

Files

Jump to
Readme
63 Versions
0 Dependencies
Dependants
Files
Activity
rocksdb c_src CMake FindRocksDB.cmake
Raw

c_src/CMake/FindRocksDB.cmake 

# Try to find RocksDB headers and library.

#

# Usage of this module as follows:

#

#     find_package(RocksDB)

#

# Variables used by this module, they can change the default behaviour and need

# to be set before calling find_package:

#

#  ROCKSDB_ROOT_DIR          Set this variable to the root installation of

#                            RocksDB if the module has problems finding the

#                            proper installation path.

#

# Variables defined by this module:

#

#  ROCKSDB_FOUND               System has RocksDB library/headers.

#  ROCKSDB_LIBRARIES           The RocksDB library.

#  ROCKSDB_INCLUDE_DIRS        The location of RocksDB headers.

#  ROCKSDB_VERSION             The RocksDB version



find_path(ROCKSDB_ROOT_DIR

    NAMES include/rocksdb/db.h

)



find_library(ROCKSDB_LIBRARIES

    NAMES rocksdb

    HINTS ${ROCKSDB_ROOT_DIR}/lib

)



find_path(ROCKSDB_INCLUDE_DIRS

    NAMES rocksdb/db.h

    HINTS ${ROCKSDB_ROOT_DIR}/include

)



if (ROCKSDB_ROOT_DIR)

    file(STRINGS ${ROCKSDB_INCLUDE_DIRS}/rocksdb/version.h _ROCKSDB_VERSION_H_CONTENTS REGEX

      "#define[ \t]+ROCKSDB_(MAJOR|MINOR|PATCH)[ \t]+")

    if(_ROCKSDB_VERSION_H_CONTENTS MATCHES "#define[ \t]+ROCKSDB_MAJOR[ \t]+([0-9]+)")

      set(_ROCKSDB_MAJOR_VERSION "${CMAKE_MATCH_1}")

    endif()

    if(_ROCKSDB_VERSION_H_CONTENTS MATCHES "#define[ \t]+ROCKSDB_MINOR[ \t]+([0-9]+)")

      set(_ROCKSDB_MINOR_VERSION "${CMAKE_MATCH_1}")

    endif()

    if(_ROCKSDB_VERSION_H_CONTENTS MATCHES "#define[ \t]+ROCKSDB_PATCH[ \t]+([0-9]+)")

      set(_ROCKSDB_PATCH_VERSION "${CMAKE_MATCH_1}")

    endif()

    set(ROCKSDB_VERSION "${_ROCKSDB_MAJOR_VERSION}.${_ROCKSDB_MINOR_VERSION}.${_ROCKSDB_PATCH_VERSION}")

    unset(_ROCKSDB_MAJOR_VERSION)

    unset(_ROCKSDB_MINOR_VERSION)

    unset(_ROCKSDB_PATCH_VERSION)

    unset(_ROCKSDB_VERSION_H_CONTENTS)

endif(ROCKSDB_ROOT_DIR)



include(FindPackageHandleStandardArgs)

find_package_handle_standard_args(RocksDB REQUIRED_VARS

    ROCKSDB_LIBRARIES

    ROCKSDB_INCLUDE_DIRS

    VERSION_VAR

    ROCKSDB_VERSION

)



mark_as_advanced(

    ROCKSDB_ROOT_DIR

    ROCKSDB_LIBRARIES

    ROCKSDB_INCLUDE_DIRS

)