Packages

project

1.0.14
1.0.40 1.0.39 1.0.38 1.0.37 1.0.36 1.0.35 1.0.34 1.0.33 1.0.31 1.0.30 1.0.25 1.0.24 1.0.23 1.0.22 1.0.21 1.0.20 1.0.19 1.0.18 1.0.17 1.0.16 1.0.15 1.0.14 1.0.13 1.0.12 1.0.11 1.0.10 1.0.9 1.0.8 1.0.7 1.0.6 1.0.5 1.0.4 1.0.3 1.0.2 1.0.1 1.0.0

Composable Igniter tasks for bootstrapping Phoenix applications

HexDocs

Current section

Files

Jump to
Readme
36 Versions
1 Dependency
Dependants
Files
Activity
project lib mix tasks project add libcluster.ex
Raw

lib/mix/tasks/project/add/libcluster.ex 

defmodule Mix.Tasks.Project.Add.Libcluster do

  @shortdoc "Adds libcluster for node clustering"

  @moduledoc "Adds `libcluster` for clustering elixir nodes."

  use Igniter.Mix.Task



  alias Mix.Tasks.Project.Helpers



  @impl Igniter.Mix.Task

  def igniter(igniter) do

    igniter

    |> add_dep()

    |> add_app_child()

    |> edit_config_dev()

  end



  defp add_dep(igniter) do

    {package, version} = Igniter.Project.Deps.determine_dep_type_and_version!("libcluster")

    Igniter.Project.Deps.add_dep(igniter, {package, version})

  end



  defp add_app_child(igniter) do

    app_module = Helpers.app_module(igniter)

    supervisor = Module.concat([app_module, "ClusterSupervisor"])

    repo = Helpers.repo(igniter)



    child =

      {Cluster.Supervisor,

       {:code,

        quote(

          do: [Application.get_env(:libcluster, :topologies) || [], [name: unquote(supervisor)]]

        )}}



    Igniter.Project.Application.add_new_child(igniter, child, after: [repo])

  end



  defp edit_config_dev(igniter) do

    opts = {:code, quote(do: [gossip: [strategy: Cluster.Strategy.Gossip]])}



    Igniter.Project.Config.configure(igniter, "dev.exs", :libcluster, [:topologies], opts)

  end

end