Packages

pow

0.1.0-alpha.1
1.0.39 1.0.38 1.0.37 1.0.36 1.0.35 1.0.34 1.0.33 1.0.32 1.0.31 1.0.30 1.0.29 1.0.28 1.0.27 1.0.26 1.0.25 1.0.24 1.0.23 1.0.22 1.0.21 1.0.20 1.0.19 1.0.18 1.0.17 1.0.16 1.0.15 1.0.14 1.0.13 1.0.12 1.0.11 1.0.10 1.0.9 1.0.8 1.0.7 1.0.6 1.0.5 1.0.4 1.0.3 1.0.2 1.0.1 1.0.0 1.0.0-rc.4 1.0.0-rc.3 1.0.0-rc.2 1.0.0-rc.1 1.0.0-rc.0 0.1.0-rc.1 0.1.0-alpha.8 0.1.0-alpha.7 retired 0.1.0-alpha.6 0.1.0-alpha.5 0.1.0-alpha.4 0.1.0-alpha.3 0.1.0-alpha.2 0.1.0-alpha.1 0.1.0-alpha

Robust user authentication solution

Security advisory: This version has known vulnerabilities. View advisories
HexDocs

Current section

Files

Jump to
Readme
55 Versions
5 Dependencies
Dependants
2 Advisories
Files
Activity
pow lib pow phoenix controllers session_controller.ex
Raw

lib/pow/phoenix/controllers/session_controller.ex 

defmodule Pow.Phoenix.SessionController do

  @moduledoc false

  use Pow.Phoenix.Controller



  alias Plug.Conn

  alias Pow.Plug



  plug :require_not_authenticated when action in [:new, :create]

  plug :require_authenticated when action in [:delete]

  plug :assign_request_path when action in [:new, :create]

  plug :assign_create_path when action in [:new, :create]



  @spec process_new(Conn.t(), map()) :: {:ok, map(), Conn.t()}

  def process_new(conn, _params) do

    {:ok, Plug.change_user(conn), conn}

  end



  @spec respond_new({:ok, map(), Conn.t()}) :: Conn.t()

  def respond_new({:ok, changeset, conn}) do

    conn

    |> assign(:changeset, changeset)

    |> render("new.html")

  end



  @spec process_create(Conn.t(), map()) :: {:ok | :error, map(), Conn.t()}

  def process_create(conn, %{"user" => user_params}) do

    Plug.authenticate_user(conn, user_params)

  end



  @spec respond_create({:ok | :error, map(), Conn.t()}) :: Conn.t()

  def respond_create({:ok, _user, conn}) do

    conn

    |> put_flash(:info, messages(conn).signed_in(conn))

    |> redirect(to: routes(conn).after_sign_in_path(conn))

  end

  def respond_create({:error, changeset, conn}) do

    conn

    |> assign(:changeset, changeset)

    |> put_flash(:error, messages(conn).invalid_credentials(conn))

    |> render("new.html")

  end



  @spec process_delete(Conn.t(), map()) :: {:ok, Conn.t()}

  def process_delete(conn, _params), do: Plug.clear_authenticated_user(conn)



  @spec respond_delete({:ok, Conn.t()}) :: Conn.t()

  def respond_delete({:ok, conn}) do

    conn

    |> put_flash(:info, messages(conn).signed_out(conn))

    |> redirect(to: routes(conn).after_sign_out_path(conn))

  end



  defp assign_request_path(%{params: %{"request_path" => request_path}} = conn, _opts) do

    Conn.assign(conn, :request_path, request_path)

  end

  defp assign_request_path(conn, _opts), do: conn



  defp assign_create_path(conn, _opts) do

    Conn.assign(conn, :action, create_path(conn))

  end



  defp create_path(%{assigns: %{request_path: request_path}} = conn) do

    create_path(conn, request_path: request_path)

  end

  defp create_path(conn, params \\ []) do

    router_helpers(conn).pow_session_path(conn, :create, params)

  end

end