Packages

posthog

2.1.0
2.12.0 2.11.1 2.11.0 2.10.3 2.10.2 2.10.1 2.10.0 2.9.2 2.9.1 2.9.0 2.8.4 2.8.3 2.8.2 2.8.1 2.8.0 2.7.1 2.7.0 2.6.1 2.6.0 2.5.0 2.4.0 2.3.0 2.2.0 2.1.0 2.0.0 1.1.0 1.0.3 1.0.2 1.0.1 1.0.0 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.0 0.2.0 0.1.0

Official PostHog Elixir SDK

HexDocs

Current section

Files

Jump to
Readme
38 Versions
4 Dependencies
Dependants
Files
Activity
posthog lib posthog context.ex
Raw

lib/posthog/context.ex 

defmodule PostHog.Context do

  @moduledoc false



  @logger_metadata_key :__posthog__



  def logger_metadata_key(), do: @logger_metadata_key



  def set(name_scope, event_scope \\ :all, context) do

    metadata =

      with :undefined <- :logger.get_process_metadata(), do: %{}



    current_context = Map.get(metadata, @logger_metadata_key, %{})



    new_value =

      case get_in(current_context, [name_scope, event_scope]) do

        %{} = existing -> Map.merge(existing, context)

        nil -> context

      end



    updated_context =

      put_in(

        current_context,

        [Access.key(name_scope, %{}), Access.key(event_scope, %{})],

        new_value

      )



    :logger.update_process_metadata(%{@logger_metadata_key => updated_context})

  end



  def get(name_scope, event_scope \\ :all) do

    case :logger.get_process_metadata() do

      %{@logger_metadata_key => context} ->

        get_in(context, [key_and_all(name_scope), key_and_all(event_scope)]) |> Map.new()



      _ ->

        %{}

    end

  end



  defp key_and_all(key) do

    fn :get, data, next ->

      scoped = Map.get(data, key, %{})

      all = Map.get(data, :all, %{})

      Enum.flat_map([all, scoped], next)

    end

  end

end