Packages

phoenix_live_dashboard

0.7.2
0.8.7 0.8.6 0.8.5 0.8.4 0.8.4-rc.0 0.8.3 0.8.2 0.8.1 0.8.0 0.7.2 0.7.1 0.7.0 0.6.5 0.6.4 0.6.3 0.6.2 0.6.1 0.6.0 0.5.3 0.5.2 0.5.1 0.5.0 0.4.0 0.3.6 0.3.5 0.3.4 retired 0.3.3 0.3.2 0.3.1 0.3.0 0.2.10 0.2.9 0.2.8 0.2.7 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.2.0 0.1.1 0.1.0

Real-time performance dashboard for Phoenix

HexDocs

Current section

Files

Jump to
Readme
43 Versions
6 Dependencies
Dependants
Files
Activity
phoenix_live_dashboard lib phoenix live_dashboard logger_pubsub_backend.ex
Raw

lib/phoenix/live_dashboard/logger_pubsub_backend.ex 

defmodule Phoenix.LiveDashboard.LoggerPubSubBackend do

  @moduledoc false



  @behaviour :gen_event



  @impl true

  def init(_) do

    config = Application.get_env(:logger, :console)

    format = Logger.Formatter.compile(Keyword.get(config, :format))

    metadata = Keyword.get(config, :metadata, []) |> configure_metadata()

    {:ok, {format, metadata}}

  end



  @impl true

  def handle_call({:configure, _options}, state) do

    {:ok, :ok, state}

  end



  @impl true

  def handle_event({level, gl, {Logger, msg, ts, metadata}}, {format, keys} = state)

      when node(gl) == node() do

    with {pubsub, topic} <- metadata[:logger_pubsub_backend] do

      metadata = take_metadata(metadata, keys)

      formatted = Logger.Formatter.format(format, level, msg, ts, metadata)

      Phoenix.PubSub.broadcast(pubsub, topic, {:logger, level, formatted})

    end



    {:ok, state}

  end



  def handle_event(_, state) do

    {:ok, state}

  end



  @impl true

  def handle_info(_, state) do

    {:ok, state}

  end



  defp configure_metadata(:all), do: :all

  defp configure_metadata(metadata), do: Enum.reverse(metadata)



  defp take_metadata(metadata, :all) do

    metadata

  end



  defp take_metadata(metadata, keys) do

    Enum.reduce(keys, [], fn key, acc ->

      case Keyword.fetch(metadata, key) do

        {:ok, val} -> [{key, val} | acc]

        :error -> acc

      end

    end)

  end

end