Packages

paper_tiger

1.2.1
1.2.2 1.2.1 1.2.0 1.1.2 1.1.1 1.1.0 1.0.2 1.0.1 1.0.0 0.9.25 0.9.24 0.9.23 0.9.22 0.9.21 0.9.20 0.9.19 0.9.18 0.9.17 0.9.16 0.9.15 0.9.14 0.9.13 0.9.12 0.9.11 0.9.10 0.9.9 0.9.8 0.9.6 0.9.5 0.9.4 0.9.2 0.9.1 0.9.0 0.8.5 0.8.4 0.8.3 0.8.2 0.8.1 0.8.0 0.7.1 0.7.0

A stateful mock Stripe server for testing Elixir applications

HexDocs

Current section

Files

Jump to
Readme
41 Versions
5 Dependencies
Dependants
Files
Activity
paper_tiger lib paper_tiger plugs connect_context.ex
Raw

lib/paper_tiger/plugs/connect_context.ex 

defmodule PaperTiger.Plugs.ConnectContext do

  @moduledoc """

  Applies Stripe Connect request context from the `Stripe-Account` header.



  The header must contain an existing connected account ID. Once accepted,

  normal resource stores scope reads and writes to that connected account for

  the rest of the request.

  """



  @behaviour Plug



  import Plug.Conn



  alias PaperTiger.Connect

  alias PaperTiger.Resource

  alias PaperTiger.Store.Accounts



  @impl true

  def init(opts), do: opts



  @impl true

  def call(conn, _opts) do

    case get_req_header(conn, "stripe-account") do

      [] ->

        Connect.clear_account()

        conn



      [account_id | _] ->

        connect_as(conn, account_id)

    end

  end



  defp connect_as(conn, account_id) do

    cond do

      not Connect.account_id?(account_id) ->

        conn

        |> Resource.error_response(PaperTiger.Error.invalid_request("Invalid Stripe-Account header", "Stripe-Account"))

        |> halt()



      account_exists?(account_id) ->

        Connect.put_account(account_id)

        assign(conn, :stripe_account, account_id)



      true ->

        conn

        |> Resource.error_response(PaperTiger.Error.not_found("account", account_id))

        |> halt()

    end

  end



  defp account_exists?(account_id) do

    Connect.without_account(fn ->

      match?({:ok, _account}, Accounts.get(account_id))

    end)

  end

end