Packages

mpeg_ts

3.3.10
3.3.19 3.3.18 3.3.17 3.3.16 3.3.14 3.3.13 3.3.12 3.3.11 3.3.10 3.3.9 3.3.8 3.3.7 3.3.6 3.3.5 3.3.4 3.3.3 3.3.2 3.3.1 3.3.0 3.2.4 3.2.3 3.2.2 3.2.1 3.2.0 3.1.0 3.0.0 2.2.0 2.0.2 2.0.1 2.0.0 1.0.2 1.0.1 1.0.0

MPEG Transport Stream (TS) library.

HexDocs

Current section

Files

Jump to
Readme
33 Versions
0 Dependencies
Dependants
Files
Activity
mpeg_ts lib mpeg ts pat.ex
Raw

lib/mpeg/ts/pat.ex 

defmodule MPEG.TS.PAT do

  @behaviour MPEG.TS.Unmarshaler



  @moduledoc """

  Program Association Table.

  """



  @type program_id_t :: 0..65_535

  @type program_pid_t :: 0..8191

  @type t :: %__MODULE__{

          programs: %{required(program_id_t()) => program_pid_t()}

        }



  @entry_length 4



  defstruct programs: %{}



  # Unmarshals Program Association Table data. Each entry should be 4 bytes

  # long. If provided data length is not divisible by entry length an error

  # shall be returned.

  @impl true

  def unmarshal(data, true) when rem(byte_size(data), @entry_length) == 0 do

    programs =

      for <<program_number::16, _reserved::3, pid::13 <- data>>,

        into: %{} do

        {program_number, pid}

      end



    {:ok, %__MODULE__{programs: programs}}

  end



  def unmarshal(_, _) do

    {:error, :invalid_data}

  end



  defimpl MPEG.TS.Marshaler do

    def marshal(%{programs: programs}) do

      Enum.map_join(programs, fn {program_number, pid} ->

        <<program_number::16, 0b111::3, pid::13>>

      end)

    end

  end

end