Packages

kadabra

0.6.3
0.6.3 0.6.2 0.6.1 0.6.0 0.5.0 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.8 0.3.7 0.3.6 0.3.5 0.3.4 0.3.3 0.3.2 0.3.1 0.3.0 0.2.2 0.2.1 0.2.0 0.1.6 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0

HTTP2 client for Elixir

HexDocs

Current section

Files

Jump to
Readme
30 Versions
2 Dependencies
Dependants
Files
Activity
kadabra lib frame push_promise.ex
Raw

lib/frame/push_promise.ex 

defmodule Kadabra.Frame.PushPromise do

  @moduledoc false



  defstruct end_headers: false,

            header_block_fragment: nil,

            stream_id: nil



  import Bitwise



  alias Kadabra.Frame



  @type t :: %__MODULE__{

          end_headers: boolean,

          header_block_fragment: bitstring,

          stream_id: non_neg_integer

        }



  @doc ~S"""

  Initializes a new `Frame.PushPromise` given a `Frame`.



  ## Examples



      iex> frame = %Kadabra.Frame{payload: <<0::1, 3::31, 136::8>>, flags: 0x4}

      iex> Kadabra.Frame.PushPromise.new(frame)

      %Kadabra.Frame.PushPromise{stream_id: 3, header_block_fragment: <<136>>,

      end_headers: true}

  """

  @spec new(Frame.t()) :: t

  def new(%Frame{payload: <<_::1, id::31, headers::bitstring>>, flags: f}) do

    %__MODULE__{

      stream_id: id,

      header_block_fragment: headers,

      end_headers: end_headers?(f)

    }

  end



  @spec end_headers?(non_neg_integer) :: boolean

  defp end_headers?(flags) when (flags &&& 4) == 4, do: true

  defp end_headers?(_), do: false

end