Packages

jsv

0.2.0
0.21.2 0.21.1 0.21.0 0.20.0 0.19.6 0.19.5 0.19.4 0.19.3 0.19.2 0.19.1 0.19.0 0.18.3 0.18.2 0.18.1 0.18.0 0.17.1 0.17.0 0.16.0 0.15.2 0.15.1 0.15.0 0.14.0 0.13.1 0.13.0 0.12.0 0.11.5 0.11.4 0.11.3 retired 0.11.2 0.11.1 0.11.0 0.10.1 0.10.0 0.9.0 0.8.1 0.8.0 0.7.2 0.7.1 0.7.0 0.6.3 0.6.2 0.6.0 0.5.1 0.5.0 0.4.0 0.3.0 0.2.0 0.1.0

A JSON Schema Validator with complete support for the latest specifications.

HexDocs

Current section

Files

Jump to
Readme
48 Versions
5 Dependencies
Dependants
Files
Activity
jsv priv uri-template.abnf
Raw

priv/uri-template.abnf 

ALPHA          =  %x41-5A / %x61-7A   ; A-Z / a-z

DIGIT          =  %x30-39             ; 0-9

HEXDIG         =  DIGIT / "A" / "B" / "C" / "D" / "E" / "F"

                  ; case-insensitive



pct-encoded    =  "%" HEXDIG HEXDIG

unreserved     =  ALPHA / DIGIT / "-" / "." / "_" / "~"

reserved       =  gen-delims / sub-delims

gen-delims     =  ":" / "/" / "?" / "#" / "[" / "]" / "@"

sub-delims     =  "!" / "$" / "&" / "'" / "(" / ")"

                /  "*" / "+" / "," / ";" / "="



ucschar        =  %xA0-D7FF / %xF900-FDCF / %xFDF0-FFEF

                /  %x10000-1FFFD / %x20000-2FFFD / %x30000-3FFFD

                /  %x40000-4FFFD / %x50000-5FFFD / %x60000-6FFFD

                /  %x70000-7FFFD / %x80000-8FFFD / %x90000-9FFFD

                /  %xA0000-AFFFD / %xB0000-BFFFD / %xC0000-CFFFD

                /  %xD0000-DFFFD / %xE1000-EFFFD



iprivate       =  %xE000-F8FF / %xF0000-FFFFD / %x100000-10FFFD



URI-Template  = *( literals / expression )



literals      =  %x21 / %x23-24 / %x26 / %x28-3B / %x3D / %x3F-5B

              /  %x5D / %x5F / %x61-7A / %x7E / ucschar / iprivate

              /  pct-encoded

                    ; any Unicode character except: CTL, SP,

                    ;  DQUOTE, "'", "%" (aside from pct-encoded),

                    ;  "<", ">", "\", "^", "`", "{", "|", "}"



expression    =  "{" [ operator ] variable-list "}"

operator      =  op-level2 / op-level3 / op-reserve

op-level2     =  "+" / "#"

op-level3     =  "." / "/" / ";" / "?" / "&"

op-reserve    =  "=" / "," / "!" / "@" / "|"



variable-list =  varspec *( "," varspec )

varspec       =  varname [ modifier-level4 ]

varname       =  varchar *( ["."] varchar )

varchar       =  ALPHA / DIGIT / "_" / pct-encoded



modifier-level4 =  prefix / explode



prefix        =  ":" max-length

max-length    =  %x31-39 0*3DIGIT   ; positive integer < 10000



explode       =  "*"