Packages

floki

0.20.0
0.38.4 0.38.3 0.38.2 0.38.1 0.38.0 0.37.1 0.37.0 0.36.3 0.36.2 0.36.1 0.36.0 0.35.4 0.35.3 0.35.2 0.35.1 0.35.0 0.34.3 0.34.2 0.34.1 0.34.0 0.33.1 0.33.0 0.32.1 0.32.0 0.31.0 0.30.1 0.30.0 0.29.0 0.28.0 0.27.0 0.26.0 0.25.0 0.24.0 0.23.1 0.23.0 0.22.0 0.21.0 0.20.4 0.20.3 0.20.2 0.20.1 0.20.0 0.19.3 0.19.2 0.19.1 0.19.0 0.18.1 0.18.0 0.17.2 0.17.1 0.17.0 0.16.0 0.15.0 0.14.0 0.13.2 0.13.1 0.13.0 0.12.1 0.12.0 0.11.0 0.10.1 0.10.0 0.9.0 0.8.1 0.8.0 0.7.2 0.7.1 0.7.0 0.6.1 0.6.0 0.5.0 0.4.1 0.4.0 0.3.3 0.3.2 0.3.1 0.3.0 0.2.1 0.2.0 0.1.1 0.1.0 0.0.5 0.0.4 0.0.3 0.0.2 0.0.1

Floki is a simple HTML parser that enables search for nodes using CSS selectors.

HexDocs

Current section

Files

Jump to
Readme
86 Versions
2 Dependencies
Dependants
Files
Activity
floki src floki_selector_lexer.xrl
Raw

src/floki_selector_lexer.xrl 

Definitions.



IDENTIFIER = [-A-Za-z0-9_]+

QUOTED = (\"[^"]*\"|\'[^']*\')

PARENTESIS = \([^)]*\)

INT = [0-9]+

NOT = (n|N)(o|O)(t|T)

ODD = (o|O)(d|D)(d|D)

EVEN = (e|E)(v|V)(e|E)(n|N)

PSEUDO_PATT = (\+|-)?({INT})?(n|N)((\+|-){INT})?

SYMBOL = [\[\]*]

W = [\s\t\r\n\f]



Rules.



{IDENTIFIER}                         : {token, {identifier, TokenLine, TokenChars}}.

{QUOTED}                             : {token, {quoted, TokenLine, remove_wrapper(TokenChars)}}.

{SYMBOL}                             : {token, {TokenChars, TokenLine}}.

#{IDENTIFIER}                        : {token, {hash, TokenLine, tail(TokenChars)}}.

\.{IDENTIFIER}                       : {token, {class, TokenLine, tail(TokenChars)}}.

\:{NOT}\(                            : {token, {pseudo_not, TokenLine}}.

\:{IDENTIFIER}                       : {token, {pseudo, TokenLine, tail(TokenChars)}}.

\({INT}\)                            : {token, {pseudo_class_int, TokenLine, list_to_integer(remove_wrapper(TokenChars))}}.

\({ODD}\)                            : {token, {pseudo_class_odd, TokenLine}}.

\({EVEN}\)                           : {token, {pseudo_class_even, TokenLine}}.

\({PSEUDO_PATT}\)                    : {token, {pseudo_class_pattern, TokenLine, remove_wrapper(TokenChars)}}.

\({QUOTED}\)                         : {token, {pseudo_class_quoted, TokenLine, remove_wrapper(remove_wrapper(TokenChars))}}.

{W}*\)                               : {token, {close_parentesis, TokenLine}}.

~=                                   : {token, {includes, TokenLine}}.

\|=                                  : {token, {dash_match, TokenLine}}.

\^=                                  : {token, {prefix_match, TokenLine}}.

\$=                                  : {token, {sufix_match, TokenLine}}.

\*=                                  : {token, {substring_match, TokenLine}}.

=                                    : {token, {equal, TokenLine}}.

{W}*,{W}*                            : {token, {comma, TokenLine}}.

{W}*>{W}*                            : {token, {greater, TokenLine}}.

{W}*\+{W}*                           : {token, {plus, TokenLine}}.

{W}*~{W}*                            : {token, {tilde, TokenLine}}.

{W}*\|{W}*                           : {token, {namespace_pipe, TokenLine}}.

{W}+                                 : {token, {space, TokenLine}}.

.                                    : {token, {unknown, TokenLine, TokenChars}}.



Erlang code.



remove_wrapper(Chars) ->

  Len = string:len(Chars),

  string:substr(Chars, 2, Len - 2).



tail([_|T]) ->

  T.