Packages

ex_open_api_utils

0.3.1
0.17.1 0.17.0 0.16.0 0.15.0 0.14.0 0.13.1 0.13.0 0.12.0 0.11.2 0.11.1 0.11.0 0.10.0 0.9.0 0.8.1 0.8.0 0.7.3 0.7.2 0.7.0 0.6.0 0.5.7 0.5.6 0.5.5 0.5.4 0.5.3 0.5.2 0.5.1 0.5.0 0.4.8 0.4.7 0.4.6 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.4 0.3.3 0.3.2 0.3.1 0.3.0 0.2.0 0.1.0

Elixir utilities for OpenAPI 3.1 schema generation from Ecto schemas

HexDocs

Current section

Files

Jump to
Readme
43 Versions
3 Dependencies
0 Dependants
Files
Activity
ex_open_api_utils lib ex_open_api_utils json.ex
Raw

lib/ex_open_api_utils/json.ex 

defprotocol ExOpenApiUtils.Json do

  @spec to_json(Ecto.Schema.t()) :: map() | list() | atom()

  def to_json(struct)

end



defimpl ExOpenApiUtils.Json, for: Any do

  defmacro __deriving__(module, _struct, property_attrs: property_attrs) do

    quote do

      alias ExOpenApiUtils.Property



      defimpl ExOpenApiUtils.Json, for: unquote(module) do

        def to_json(arg) do

          Enum.reduce(unquote(Macro.escape(property_attrs)), %{}, fn %Property{} = property,

                                                                     acc ->

            source = property.source || property.key

            val = Map.get(arg, source) |> ExOpenApiUtils.Json.to_json()

            Map.put(acc, Atom.to_string(property.key), val)

          end)

        end

      end

    end

  end



  def to_json(_struct) do

    raise "protocol needs to be defined with properties"

  end

end



defimpl ExOpenApiUtils.Json,

  for: [

    Integer,

    String,

    BitString,

    Decimal,

    Date,

    Time,

    NaiveDateTime,

    DateTime

  ] do

  def to_json(val), do: val

end



defimpl ExOpenApiUtils.Json, for: [Map] do

  def to_json(val) do

    Enum.reduce(val, %{}, fn {k, v}, acc ->

      Map.put(acc, k, ExOpenApiUtils.Json.to_json(v))

    end)

  end

end



defimpl ExOpenApiUtils.Json, for: [List] do

  def to_json(list) do

    Enum.map(list, &ExOpenApiUtils.Json.to_json/1)

  end

end



defimpl ExOpenApiUtils.Json, for: Ecto.Association.NotLoaded  do

  def to_json(_val) do

    :not_loaded

  end

end