Packages

ex_json_schema

0.11.0
0.11.5 0.11.4 0.11.3 0.11.2 0.11.1 0.11.0 0.10.2 0.10.1 0.9.3 0.9.2 0.9.1 0.9.0 0.8.1 0.8.0-rc1 0.7.4 0.7.3 0.7.2 retired 0.7.1 0.7.0 0.6.2 0.6.1 0.6.0 0.6.0-rc.1 0.5.8 0.5.7 0.5.6 0.5.5 0.5.4 0.5.3 0.5.2 0.5.1 0.5.0 0.4.1 0.4.0 0.3.1 0.3.0 0.2.2 0.2.1 0.2.0

A JSON Schema validator with full support for the draft 4 specification and zero dependencies.

HexDocs

Current section

Files

Jump to
Readme
39 Versions
1 Dependency
Dependants
Files
Activity
ex_json_schema lib ex_json_schema validator one_of.ex
Raw

lib/ex_json_schema/validator/one_of.ex 

defmodule ExJsonSchema.Validator.OneOf do

  @moduledoc """

  `ExJsonSchema.Validator` implementation for `"oneOf"` attributes.



  See:



  """



  alias ExJsonSchema.Validator

  alias ExJsonSchema.Validator.Error



  @behaviour ExJsonSchema.Validator



  @impl ExJsonSchema.Validator

  def validate(root, _, {"oneOf", one_of}, data, path) do

    do_validate(root, one_of, data, path)

  end



  def validate(_, _, _, _, _) do

    []

  end



  defp do_validate(root, one_of, data, path) do

    {valid_count, valid_indices, errors} =

      one_of

      |> Enum.with_index()

      |> Enum.reduce({0, [], []}, fn

        {schema, index}, {valid_count, valid_indices, errors} ->

          case Validator.validation_errors(root, schema, data, path) do

            [] -> {valid_count + 1, [index | valid_indices], errors}

            e -> {valid_count, valid_indices, [{e, index} | errors]}

          end

      end)



    case valid_count do

      1 ->

        []



      0 ->

        [

          %Error{

            error: %Error.OneOf{

              valid_indices: [],

              invalid: errors |> Enum.reverse() |> Validator.map_to_invalid_errors()

            }

          }

        ]



      _ ->

        [%Error{error: %Error.OneOf{valid_indices: Enum.reverse(valid_indices), invalid: []}}]

    end

  end

end