Packages

ex_debug_toolbar

0.1.6
0.5.0 0.4.6 retired 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.15 0.3.14 0.3.12 0.3.11 0.3.10 0.3.9 0.3.8 0.3.6 0.3.5 0.3.4 0.3.3 0.3.2 0.3.1 0.3.0 0.2.3 0.2.2 0.2.1 0.2.0 0.1.19 0.1.18 0.1.17 0.1.16 0.1.15 0.1.14 0.1.13 0.1.12 0.1.11 0.1.10 0.1.9 0.1.8 0.1.7 0.1.6 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0

A debug web toolbar for Phoenix projects to display all sorts of information about request

HexDocs

Current section

Files

Jump to
Readme
46 Versions
7 Dependencies
0 Dependants
Files
Activity
ex_debug_toolbar lib ex_debug_toolbar plug code_injector.ex
Raw

lib/ex_debug_toolbar/plug/code_injector.ex 

defmodule ExDebugToolbar.Plug.CodeInjector do

  import Plug.Conn

  alias Plug.Conn

  alias ExDebugToolbar.Router.Helpers, as: RouterHelpers



  @behaviour Plug



  @path_prefix "/__ex_debug_toolbar__"



  def init(options), do: options



  def call(conn, _opts) do

    register_before_send conn, &inject_debug_toolbar_code/1

  end



  defp inject_debug_toolbar_code(conn) do

    if inject?(conn) do

      conn |> inject_css |> inject_js

    else

      conn

    end

  end



  defp inject_js(conn) do

    static_path("/js/toolbar.js") |> js_code(conn) |> inject_code(conn, "</body>")

  end



  defp inject_css(conn) do

    css_path = static_path("/css/toolbar.css")

    "<link rel='stylesheet' type='text/css' href='#{css_path}'>\n" |> inject_code(conn, "</head>")

  end



  defp static_path(path) do

    @path_prefix <> RouterHelpers.static_path(ExDebugToolbar.Endpoint, path)

  end



  defp inject_code(code, %{resp_body: body} = conn, tag) do

    body = body |> to_string |> String.replace(tag, code <> tag)

    put_in conn.resp_body, body

  end



  defp js_code(path, conn) do

    """

    <script>window.requestId='#{conn.private.request_id}';</script>

    <script src='#{path}'></script>

    """

  end



  defp inject?(%Conn{request_path: "/phoenix/live_reload/frame"}), do: false

  defp inject?(%Conn{status: status}) when status != 200, do: false

  defp inject?(%Conn{} = conn), do: html_content_type?(conn)



  defp html_content_type?(%Conn{} = conn) do

    conn |> get_resp_header("content-type") |> html_content_type?

  end

  defp html_content_type?([]), do: false

  defp html_content_type?([type | _]), do: String.starts_with?(type, "text/html")

end