Packages

ex_debug_toolbar

0.1.2
0.5.0 0.4.6 retired 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.15 0.3.14 0.3.12 0.3.11 0.3.10 0.3.9 0.3.8 0.3.6 0.3.5 0.3.4 0.3.3 0.3.2 0.3.1 0.3.0 0.2.3 0.2.2 0.2.1 0.2.0 0.1.19 0.1.18 0.1.17 0.1.16 0.1.15 0.1.14 0.1.13 0.1.12 0.1.11 0.1.10 0.1.9 0.1.8 0.1.7 0.1.6 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0

A debug web toolbar for Phoenix projects to display all sorts of information about request

HexDocs

Current section

Files

Jump to
Readme
46 Versions
7 Dependencies
0 Dependants
Files
Activity
ex_debug_toolbar lib ex_debug_toolbar database request_repo.ex
Raw

lib/ex_debug_toolbar/database/request_repo.ex 

defmodule ExDebugToolbar.Database.RequestRepo do

  use GenServer

  alias ExDebugToolbar.Request



  def insert(%Request{} = request) do

    transaction fn ->

      :mnesia.write({Request, request.pid, request.uuid, request})

    end

  end



  def update(id, changes) do

    GenServer.cast(__MODULE__, {:update, id, changes})

    :ok

  end



  def all do

    transaction fn ->

      :mnesia.select(Request, [{{Request, :"_", :"_", :"$1"},[],[:"$1"]}])

    end

  end



  def purge do

    :mnesia.clear_table(Request) |> result

  end



  def get(pid) when is_pid(pid) do

    do_get fn ->

      :mnesia.read(Request, pid)

    end

  end

  def get(uuid) do

    do_get fn ->

      :mnesia.index_read(Request, uuid, :uuid)

    end

  end



  defp do_get(func) do

    case transaction(func) do

      [{Request, _, _, request}] -> {:ok, request}

      [] -> {:error, :not_found}

    end

  end



  def start_link do

    GenServer.start_link(__MODULE__, [], name: __MODULE__)

  end



  def handle_cast({:update, id, changes}, _state) do

    transaction fn ->

      case get(id) do

        {:ok, request} -> request |> apply_changes(changes) |> insert

        _ -> :error

      end

    end

    {:noreply, nil}

  end



  defp apply_changes(request, changes) when is_map(changes) do

    Map.merge(request, changes)

  end

  defp apply_changes(request, changes) when is_function(changes) do

    changes.(request)

  end



  def transaction(func) do

    :mnesia.transaction(func) |> result 

  end



  def result({:atomic, result}), do: result

  def result({:aborted, reason}), do: {:error, reason}

end