Packages

ethers

0.6.2
0.7.0 0.6.13 0.6.12 0.6.11 0.6.10 0.6.9 0.6.8 0.6.7 0.6.6 0.6.5 0.6.4 0.6.3 0.6.2 0.6.1 0.6.0 0.5.5 0.5.4 0.5.3 0.5.2 0.5.1 0.5.0 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.3.1 0.3.0 0.2.3 0.2.2 0.2.1 0.2.0 0.1.3 0.1.2 0.1.1 0.1.0 0.0.6 0.0.5 0.0.4 0.0.3 0.0.2 0.0.1 retired 0.0.1-dev

A comprehensive Web3 library for interacting with smart contracts on Ethereum using Elixir.

HexDocs

Current section

Files

Jump to
Readme
44 Versions
8 Dependencies
Dependants
Files
Activity
ethers lib ethers rpc_client ethereumex_http_client.ex
Raw

lib/ethers/rpc_client/ethereumex_http_client.ex 

defmodule Ethers.RpcClient.EthereumexHttpClient do

  @moduledoc false



  alias Ethers.RpcClient.Adapter



  @behaviour Ethers.RpcClient.Adapter



  @exclude_delegation [:eth_get_logs]



  for {func, arity} <- Adapter.behaviour_info(:callbacks), func not in @exclude_delegation do

    args = Macro.generate_arguments(arity - 1, __MODULE__)



    @impl true

    def unquote(func)(unquote_splicing(args), opts \\ []) do

      apply(Ethereumex.HttpClient, unquote(func), [unquote_splicing(args), opts])

    end

  end



  @impl true

  def eth_get_logs(params, opts \\ []) do

    params

    |> replace_key(:from_block, :fromBlock)

    |> replace_key(:to_block, :toBlock)

    |> Ethereumex.HttpClient.eth_get_logs(opts)

  end



  defp replace_key(map, ethers_key, ethereumex_key) do

    case Map.fetch(map, ethers_key) do

      {:ok, value} ->

        map

        |> Map.put(ethereumex_key, value)

        |> Map.delete(ethers_key)



      :error ->

        map

    end

  end

end