Packages

electric_client

0.1.0-dev-5
0.10.3 0.10.2 0.10.1 0.10.1-beta-1 0.10.0 0.9.5-beta-1 0.9.4 0.9.4-beta-1 0.9.3 0.9.2 0.9.1 0.9.0 0.8.3 0.8.3-beta-1 0.8.2 0.8.1 0.8.0 0.8.0-beta-1 0.7.3 0.7.2 0.7.1 0.7.0 0.6.5 0.6.5-beta-5 0.6.5-beta-4 0.6.5-beta-3 0.6.5-beta-2 0.6.5-beta-1 0.6.4 0.6.3 0.6.2 0.6.1 0.6.0 0.5.0 0.5.0-beta-1 0.4.1 0.4.0 0.3.2 0.3.1 0.3.0 0.3.0-beta.4 0.3.0-beta.3 0.3.0-beta.2 0.2.6-pre-1 retired 0.2.6-beta.1 0.2.6-beta.0 0.2.5 0.2.4 0.2.4-pre-8 0.2.4-pre-7 0.2.4-pre-6 0.2.4-pre-5 0.2.4-pre-4 0.2.4-pre-3 0.2.4-pre-2 0.2.4-pre-1 0.2.3 0.2.3-rc-1 0.2.2 0.2.2-rc-1 0.2.1 0.2.1-rc-3 0.2.1-rc-2 0.2.1-rc-1 0.2.0 0.1.2 0.1.1 0.1.0 0.1.0-dev-9 0.1.0-dev-8 0.1.0-dev-7 0.1.0-dev-6 0.1.0-dev-5 0.1.0-dev-4 0.1.0-dev-3 0.1.0-dev-2 0.1.0-dev-17 0.1.0-dev-16 0.1.0-dev-15 0.1.0-dev-14 0.1.0-dev-13 0.1.0-dev-12 0.1.0-dev-11 0.1.0-dev-10 0.1.0-dev

Elixir client for ElectricSQL

HexDocs

Current section

Files

Jump to
Readme
85 Versions
5 Dependencies
Dependants
Files
Activity
electric_client lib electric client ecto_adapter.ex
Raw

lib/electric/client/ecto_adapter.ex 

if Code.ensure_loaded?(Ecto) do

  defmodule Electric.Client.EctoAdapter do

    @moduledoc false



    alias Electric.Client.ShapeDefinition



    @behaviour Electric.Client.ValueMapper



    @doc false

    @spec shape_from_query!(Ecto.Queryable.t()) :: {ShapeDefinition.t(), {module(), module()}}

    def shape_from_query!(queryable) do

      query = Ecto.Queryable.to_query(queryable)



      validate_query!(query)



      {table_name, namespace, struct} = table_name(query)



      where = where_clause(query)



      {ShapeDefinition.new(table_name, namespace: namespace, where: where), {__MODULE__, struct}}

    end



    defp table_name(%{from: %{prefix: prefix, source: {table_name, struct}}}) do

      {table_name, prefix, struct}

    end



    defp where_clause(query) do

      %{from: %{source: {table_name, struct}}} = query



      {query, [], _key} =

        Ecto.Query.Planner.plan(query, :all, Ecto.Adapters.Postgres)



      {query, _} = Ecto.Query.Planner.normalize(query, :all, Ecto.Adapters.Postgres, 1)



      query

      |> Electric.Client.EctoAdapter.Postgres.where(

        {{quote_table(table_name), quote_table(table_name), struct}, []}

      )

      |> case do

        [] -> nil

        iodata -> IO.iodata_to_binary(iodata)

      end

    end



    defp quote_table(table_name) do

      [34, table_name, 34]

    end



    @impl Electric.Client.ValueMapper

    def for_schema(_schema, module) do

      fields =

        Enum.map(module.__schema__(:fields), fn field ->

          {module.__schema__(:field_source, field) |> to_string(), field,

           cast_to(module.__schema__(:type, field))}

        end)



      &map_values(&1, module, fields)

    end



    defp map_values(values, module, fields) do

      struct(

        module,

        Enum.map(fields, fn {column, field, fun} ->

          {field, fun.(Map.get(values, column))}

        end)

      )

    end



    defp cast_to(:boolean) do

      fn

        nil -> nil

        "t" -> true

        "f" -> false

        value -> Ecto.Type.cast!(:boolean, value)

      end

    end



    defp cast_to(type) do

      fn

        nil -> nil

        value -> Ecto.Type.cast!(type, value)

      end

    end



    @problematic_clauses [

      joins: "JOIN",

      updates: "UPDATE",

      order_bys: "ORDER BY",

      havings: "HAVING",

      group_bys: "GROUP BY",

      distinct: "DISTINCT"

    ]



    for {key, name} <- @problematic_clauses do

      defp validate_query!(%{unquote(key) => [_ | _]}),

        do:

          raise(ArgumentError,

            message: "Electric does not support streaming queries with #{unquote(name)} clauses"

          )

    end



    defp validate_query!(_query), do: :ok

  end

end