Packages
credo
1.7.7
1.7.19
1.7.18
1.7.17
1.7.16
1.7.15
1.7.14
1.7.13
1.7.12
1.7.11
1.7.10
1.7.9
1.7.8
1.7.7
1.7.7-rc.0
1.7.6
1.7.5
1.7.4
1.7.3
1.7.2
1.7.2-rc.4
1.7.2-rc.3
1.7.2-rc.2
1.7.2-rc.1
1.7.2-rc.0
1.7.1
1.7.0
1.7.0-rc.2
1.7.0-rc.1
1.6.7
1.6.6
1.6.5
1.6.4
1.6.3
1.6.2
1.6.1
1.6.0
1.6.0-rc.1
1.6.0-rc.0
1.5.6
1.5.5
1.5.4
1.5.3
1.5.2
1.5.1
1.5.0
1.5.0-rc.5
1.5.0-rc.4
1.5.0-rc.3
1.5.0-rc.2
1.5.0-rc.1
1.4.1
1.4.0
1.4.0-rc.2
1.4.0-rc.1
1.3.2
1.3.1
1.3.0
1.3.0-rc3
1.3.0-rc2
1.3.0-rc1
1.2.3
1.2.2
1.2.1
1.2.0
1.2.0-rc4
1.2.0-rc3
1.2.0-rc2
1.2.0-rc1
1.1.5
1.1.4
1.1.3
1.1.2
1.1.1
1.1.0
1.1.0-rc3
1.1.0-rc2
1.1.0-rc1
1.0.5
1.0.4
1.0.3
1.0.2
1.0.1
1.0.1-rc1
1.0.0
1.0.0-rc1
0.10.2
0.10.1
0.10.0
0.9.3
0.9.2
0.9.1
0.9.0
0.9.0-rc8
0.9.0-rc7
0.9.0-rc6
0.9.0-rc5
0.9.0-rc4
0.9.0-rc3
0.9.0-rc2
0.9.0-rc1
0.8.10
0.8.9
0.8.8
0.8.7
0.8.6
0.8.5
0.8.4
0.8.3
0.8.2
0.8.1
0.8.0
0.8.0-rc7
0.8.0-rc6
0.8.0-rc5
0.8.0-rc4
0.8.0-rc3
0.8.0-rc2
0.8.0-rc1
0.7.4
0.7.3
0.7.2
0.7.1
0.7.0
0.6.1
0.6.0
0.6.0-rc2
0.6.0-rc1
0.5.3
0.5.2
0.5.1
0.5.0
0.4.14
0.4.13
0.4.12
0.4.11
0.4.10
0.4.10-dev
0.4.9
0.4.8
0.4.7
0.4.6
0.4.5
0.4.4
0.4.3
0.4.2
0.4.1
0.4.0
0.4.0-beta5
0.4.0-beta4
0.4.0-beta3
0.4.0-beta2
0.4.0-beta1
0.3.13
0.3.12
0.3.11
0.3.10
0.3.9
0.3.8
0.3.7
0.3.6
0.3.5
0.3.4
0.3.3
0.3.2
0.3.1
0.3.0
0.3.0-dev2
0.3.0-dev
0.2.6
0.2.5
0.2.4
0.2.3
0.2.2
0.2.1
0.2.0
0.1.10
0.1.9
0.1.8
0.1.7
0.1.6
0.1.5
0.1.4
0.1.3
0.1.2
0.1.1
0.1.0
0.0.1-dev
A static code analysis tool with a focus on code consistency and teaching.
Current section
Files
Jump to
Current section
Files
lib/credo/check/warning/lazy_logging.ex
defmodule Credo.Check.Warning.LazyLogging do
use Credo.Check,
id: "EX5007",
base_priority: :high,
elixir_version: "< 1.7.0",
param_defaults: [
ignore: [:error, :warn, :info]
],
explanations: [
check: """
Ensures laziness of Logger calls.
You will want to wrap expensive logger calls into a zero argument
function (`fn -> "string that gets logged" end`).
Example:
# preferred
Logger.debug fn ->
"This happened: \#{expensive_calculation(arg1, arg2)}"
end
# NOT preferred
# the interpolation is executed whether or not the info is logged
Logger.debug "This happened: \#{expensive_calculation(arg1, arg2)}"
""",
params: [
ignore: "Do not raise an issue for these Logger calls."
]
]
@logger_functions [:debug, :info, :warn, :error]
@doc false
@impl true
def run(%SourceFile{} = source_file, params) do
issue_meta = IssueMeta.for(source_file, params)
# {<Logger import seen?>, <list of issues>}
state = {false, []}
{_, issues} = Credo.Code.prewalk(source_file, &traverse(&1, &2, issue_meta), state)
issues
end
defp traverse(
{{:., _, [{:__aliases__, meta, [:Logger]}, fun_name]}, _, arguments} = ast,
state,
issue_meta
)
when fun_name in @logger_functions do
trigger = "Logger.#{fun_name}"
issue = find_issue(fun_name, arguments, meta, issue_meta, trigger)
{ast, add_issue_to_state(state, issue)}
end
defp traverse(
{fun_name, meta, arguments} = ast,
{true, _issues} = state,
issue_meta
)
when fun_name in @logger_functions do
issue = find_issue(fun_name, arguments, meta, issue_meta, fun_name)
{ast, add_issue_to_state(state, issue)}
end
defp traverse(
{:import, _meta, arguments} = ast,
{_module_contains_import?, issues} = state,
_issue_meta
) do
if logger_import?(arguments) do
{ast, {true, issues}}
else
{ast, state}
end
end
defp traverse(ast, state, _issue_meta) do
{ast, state}
end
defp add_issue_to_state(state, nil), do: state
defp add_issue_to_state({module_contains_import?, issues}, issue) do
{module_contains_import?, [issue | issues]}
end
defp find_issue(fun_name, arguments, meta, issue_meta, trigger) do
params = IssueMeta.params(issue_meta)
ignored_functions = Params.get(params, :ignore, __MODULE__)
unless Enum.member?(ignored_functions, fun_name) do
issue_for_call(arguments, meta, trigger, issue_meta)
end
end
defp issue_for_call([{:<<>>, _, [_ | _]} | _] = _args, meta, fun_name, issue_meta) do
issue_for(issue_meta, meta, fun_name)
end
defp issue_for_call(_args, _meta, _trigger, _issue_meta) do
nil
end
defp logger_import?([{:__aliases__, _meta, [:Logger]}]), do: true
defp logger_import?(_), do: false
defp issue_for(issue_meta, meta, trigger) do
format_issue(
issue_meta,
message: "Prefer lazy Logger calls.",
line_no: meta[:line],
column: meta[:column],
trigger: trigger
)
end
end