Packages
credo
1.3.1
1.7.19
1.7.18
1.7.17
1.7.16
1.7.15
1.7.14
1.7.13
1.7.12
1.7.11
1.7.10
1.7.9
1.7.8
1.7.7
1.7.7-rc.0
1.7.6
1.7.5
1.7.4
1.7.3
1.7.2
1.7.2-rc.4
1.7.2-rc.3
1.7.2-rc.2
1.7.2-rc.1
1.7.2-rc.0
1.7.1
1.7.0
1.7.0-rc.2
1.7.0-rc.1
1.6.7
1.6.6
1.6.5
1.6.4
1.6.3
1.6.2
1.6.1
1.6.0
1.6.0-rc.1
1.6.0-rc.0
1.5.6
1.5.5
1.5.4
1.5.3
1.5.2
1.5.1
1.5.0
1.5.0-rc.5
1.5.0-rc.4
1.5.0-rc.3
1.5.0-rc.2
1.5.0-rc.1
1.4.1
1.4.0
1.4.0-rc.2
1.4.0-rc.1
1.3.2
1.3.1
1.3.0
1.3.0-rc3
1.3.0-rc2
1.3.0-rc1
1.2.3
1.2.2
1.2.1
1.2.0
1.2.0-rc4
1.2.0-rc3
1.2.0-rc2
1.2.0-rc1
1.1.5
1.1.4
1.1.3
1.1.2
1.1.1
1.1.0
1.1.0-rc3
1.1.0-rc2
1.1.0-rc1
1.0.5
1.0.4
1.0.3
1.0.2
1.0.1
1.0.1-rc1
1.0.0
1.0.0-rc1
0.10.2
0.10.1
0.10.0
0.9.3
0.9.2
0.9.1
0.9.0
0.9.0-rc8
0.9.0-rc7
0.9.0-rc6
0.9.0-rc5
0.9.0-rc4
0.9.0-rc3
0.9.0-rc2
0.9.0-rc1
0.8.10
0.8.9
0.8.8
0.8.7
0.8.6
0.8.5
0.8.4
0.8.3
0.8.2
0.8.1
0.8.0
0.8.0-rc7
0.8.0-rc6
0.8.0-rc5
0.8.0-rc4
0.8.0-rc3
0.8.0-rc2
0.8.0-rc1
0.7.4
0.7.3
0.7.2
0.7.1
0.7.0
0.6.1
0.6.0
0.6.0-rc2
0.6.0-rc1
0.5.3
0.5.2
0.5.1
0.5.0
0.4.14
0.4.13
0.4.12
0.4.11
0.4.10
0.4.10-dev
0.4.9
0.4.8
0.4.7
0.4.6
0.4.5
0.4.4
0.4.3
0.4.2
0.4.1
0.4.0
0.4.0-beta5
0.4.0-beta4
0.4.0-beta3
0.4.0-beta2
0.4.0-beta1
0.3.13
0.3.12
0.3.11
0.3.10
0.3.9
0.3.8
0.3.7
0.3.6
0.3.5
0.3.4
0.3.3
0.3.2
0.3.1
0.3.0
0.3.0-dev2
0.3.0-dev
0.2.6
0.2.5
0.2.4
0.2.3
0.2.2
0.2.1
0.2.0
0.1.10
0.1.9
0.1.8
0.1.7
0.1.6
0.1.5
0.1.4
0.1.3
0.1.2
0.1.1
0.1.0
0.0.1-dev
A static code analysis tool with a focus on code consistency and teaching.
Current section
Files
Jump to
Current section
Files
lib/credo/check/refactor/with_clauses.ex
defmodule Credo.Check.Refactor.WithClauses do
use Credo.Check,
base_priority: :high,
explanations: [
check: ~S"""
`with` statements are useful when you need to chain a sequence
of pattern matches, stopping at the first one that fails.
However, there are a few cases where a `with` can be used incorrectly.
## Starting or ending with non-pattern-matching clauses
If the `with` starts or ends with clauses that are not `<-` clauses,
then those clauses should be moved either outside of the `with` (if
they're the first ones) or inside the body of the `with` (if they're the
last ones). For example look at this code:
with ref = make_ref(),
{:ok, user} <- User.create(ref),
Logger.debug("Created user: #{inspect(user)}") do
user
end
This `with` should be refactored like this:
ref = make_ref()
with {:ok, user} <- User.create(ref) do
Logger.debug("Created user: #{inspect(user)}")
user
end
# Using only one pattern matching clause with `else`
If the `with` has a single pattern matching clause and no `else`
branch, it means that if the clause doesn't match than the whole
`with` will return the value of that clause. However, if that
`with` has also an `else` clause, then you're using `with` exactly
like a `case` and a `case` should be used instead. Take this code:
with {:ok, user} <- User.create(make_ref()) do
user
else
{:error, :db_down} ->
raise "DB is down!"
{:error, reason} ->
raise "error: #{inspect(reason)}"
end
It can be rewritten with a clearer use of `case`:
case User.create(make_ref()) do
{:ok, user} ->
user
{:error, :db_down} ->
raise "DB is down!"
{:error, reason} ->
raise "error: #{inspect(reason)}"
end
Like all `Readability` issues, this one is not a technical concern.
But you can improve the odds of others reading and liking your code by making
it easier to follow.
""",
params: []
]
alias Credo.Code
@message_only_one_pattern_clause "\"with\" contains only one <- clause and an \"else\" " <>
"branch, use a \"case\" instead"
@message_first_clause_not_pattern "\"with\" doesn't start with a <- clause, " <>
"move the non-pattern <- clauses outside of the \"with\""
@message_last_clause_not_pattern "\"with\" doesn't end with a <- clause, move " <>
"the non-pattern <- clauses inside the body of the \"with\""
@doc false
def run(source_file, params \\ []) do
issue_meta = IssueMeta.for(source_file, params)
Code.prewalk(source_file, &traverse(&1, &2, issue_meta))
end
defp traverse({:with, meta, [_, _ | _] = clauses_and_body} = ast, issues, issue_meta)
when is_list(clauses_and_body) do
# If clauses_and_body is a list with at least two elements in it, we think
# this might be a call to the special form "with". To be sure of that,
# we get the last element of clauses_and_body and check that it's a keyword
# list with a :do key in it (the body).
# We can hard-match on [maybe_body] here since we know that clauses_and_body
# has at least two elements.
{maybe_clauses, [maybe_body]} = Enum.split(clauses_and_body, -1)
if Keyword.keyword?(maybe_body) and Keyword.has_key?(maybe_body, :do) do
{ast, issues_for_with(maybe_clauses, maybe_body, meta[:line], issue_meta) ++ issues}
else
{ast, issues}
end
end
defp traverse(ast, issues, _issue_meta) do
{ast, issues}
end
defp issues_for_with(clauses, body, line, issue_meta) do
issue_if_one_pattern_clause_with_else(clauses, body, line, issue_meta) ++
issue_if_not_starting_with_pattern_clause(clauses, line, issue_meta) ++
issue_if_not_ending_with_pattern_clause(clauses, line, issue_meta)
end
defp issue_if_one_pattern_clause_with_else(clauses, body, line, issue_meta) do
pattern_clauses_count = Enum.count(clauses, &match?({:<-, _, _}, &1))
if pattern_clauses_count <= 1 and Keyword.has_key?(body, :else) do
[format_issue(issue_meta, message: @message_only_one_pattern_clause, line_no: line)]
else
[]
end
end
defp issue_if_not_starting_with_pattern_clause(
[{:<-, _meta, _args} | _rest],
_line,
_issue_meta
) do
[]
end
defp issue_if_not_starting_with_pattern_clause(_clauses, line, issue_meta) do
[format_issue(issue_meta, message: @message_first_clause_not_pattern, line_no: line)]
end
defp issue_if_not_ending_with_pattern_clause(clauses, line, issue_meta) do
if length(clauses) > 1 and not match?({:<-, _, _}, Enum.at(clauses, -1)) do
[format_issue(issue_meta, message: @message_last_clause_not_pattern, line_no: line)]
else
[]
end
end
end