Packages

credo

0.3.0-dev2
1.7.19 1.7.18 1.7.17 1.7.16 1.7.15 1.7.14 1.7.13 1.7.12 1.7.11 1.7.10 1.7.9 1.7.8 1.7.7 1.7.7-rc.0 1.7.6 1.7.5 1.7.4 1.7.3 1.7.2 1.7.2-rc.4 1.7.2-rc.3 1.7.2-rc.2 1.7.2-rc.1 1.7.2-rc.0 1.7.1 1.7.0 1.7.0-rc.2 1.7.0-rc.1 1.6.7 1.6.6 1.6.5 1.6.4 1.6.3 1.6.2 1.6.1 1.6.0 1.6.0-rc.1 1.6.0-rc.0 1.5.6 1.5.5 1.5.4 1.5.3 1.5.2 1.5.1 1.5.0 1.5.0-rc.5 1.5.0-rc.4 1.5.0-rc.3 1.5.0-rc.2 1.5.0-rc.1 1.4.1 1.4.0 1.4.0-rc.2 1.4.0-rc.1 1.3.2 1.3.1 1.3.0 1.3.0-rc3 1.3.0-rc2 1.3.0-rc1 1.2.3 1.2.2 1.2.1 1.2.0 1.2.0-rc4 1.2.0-rc3 1.2.0-rc2 1.2.0-rc1 1.1.5 1.1.4 1.1.3 1.1.2 1.1.1 1.1.0 1.1.0-rc3 1.1.0-rc2 1.1.0-rc1 1.0.5 1.0.4 1.0.3 1.0.2 1.0.1 1.0.1-rc1 1.0.0 1.0.0-rc1 0.10.2 0.10.1 0.10.0 0.9.3 0.9.2 0.9.1 0.9.0 0.9.0-rc8 0.9.0-rc7 0.9.0-rc6 0.9.0-rc5 0.9.0-rc4 0.9.0-rc3 0.9.0-rc2 0.9.0-rc1 0.8.10 0.8.9 0.8.8 0.8.7 0.8.6 0.8.5 0.8.4 0.8.3 0.8.2 0.8.1 0.8.0 0.8.0-rc7 0.8.0-rc6 0.8.0-rc5 0.8.0-rc4 0.8.0-rc3 0.8.0-rc2 0.8.0-rc1 0.7.4 0.7.3 0.7.2 0.7.1 0.7.0 0.6.1 0.6.0 0.6.0-rc2 0.6.0-rc1 0.5.3 0.5.2 0.5.1 0.5.0 0.4.14 0.4.13 0.4.12 0.4.11 0.4.10 0.4.10-dev 0.4.9 0.4.8 0.4.7 0.4.6 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.4.0 0.4.0-beta5 0.4.0-beta4 0.4.0-beta3 0.4.0-beta2 0.4.0-beta1 0.3.13 0.3.12 0.3.11 0.3.10 0.3.9 0.3.8 0.3.7 0.3.6 0.3.5 0.3.4 0.3.3 0.3.2 0.3.1 0.3.0 0.3.0-dev2 0.3.0-dev 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.2.0 0.1.10 0.1.9 0.1.8 0.1.7 0.1.6 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0 0.0.1-dev

A static code analysis tool with a focus on code consistency and teaching.

HexDocs

Current section

Files

Jump to
Readme
187 Versions
1 Dependency
Dependants
Files
Activity
credo lib credo check warning name_redeclaration_by_case.ex
Raw

lib/credo/check/warning/name_redeclaration_by_case.ex 

defmodule Credo.Check.Warning.NameRedeclarationByCase do

  @moduledoc """

  Names assigned to choices in a `case` statement should not be the same as

  names of functions in the same module or in `Kernel`.



  Example:



      def handle_something(foo, bar) do

        case foo do

          nil -> bar

          time ->

            Logger.debug "Request handled"

            time   # are we talking about time/0 or the value of foo here?

        end

      end



      def time do

        TimeHelper.now

      end



  This might not seem like a big deal, especially for small functions.

  But there is no downside to avoiding it, especially in the case of functions

  with arity `/0` and Kernel functions.



  True story: You might pattern match on a parameter geniusly called `node`.

  Then you remove that match for some reason and rename the parameter to `_node`

  because it is no longer used.

  Later you reintroduce the pattern match on `node` but forget to also rename

  `_node` and suddenly the match is actually against `Kernel.node/0` and has the

  weirdest side effects.



  This happens. I mean, to a friend of mine, it did. Who ... later told me.

  """



  @explanation [check: @moduledoc]

  @kernel_fun_names [

    :abs,

    :apply,

    :binary_part,

    :bit_size,

    :byte_size,

    :div,

    :elem,

    :exit,

    :function_exported?,

    :get_and_update_in,

    :get_in,

    :hd,

    :inspect,

    :is_atom,

    :is_binary,

    :is_bitstring,

    :is_boolean,

    :is_float,

    :is_function,

    :is_integer,

    :is_list,

    :is_map,

    :is_number,

    :is_pid,

    :is_port,

    :is_reference,

    :is_tuple,

    :length,

    :macro_exported?,

    :make_ref,

    :map_size,

    :max,

    :min,

    :node,

    :not,

    :put_elem,

    :put_in,

    :rem,

    :round,

    :self,

    :send,

    :spawn,

    :spawn_link,

    :spawn_monitor,

    :struct,

    :throw,

    :tl,

    :trunc,

    :tuple_size,

    :update_in,

  ]

  @kernel_macro_names [

    :alias!,

    :and,

    :binding,

    :def,

    :defdelegate,

    :defexception,

    :defimpl,

    :defmacro,

    :defmacrop,

    :defmodule,

    :defoverridable,

    :defp,

    :defprotocol,

    :defstruct,

    :destructure,

    :get_and_update_in,

    :if,

    :in,

    :is_nil,

    :match?,

    :or,

    :put_in,

    :raise,

    :reraise,

    :sigil_C,

    :sigil_R,

    :sigil_S,

    :sigil_W,

    :sigil_c,

    :sigil_r,

    :sigil_s,

    :sigil_w,

    :to_char_list,

    :to_string,

    :unless,

    :update_in,

    :use,

    :var!,

  ]

  @excluded_names [:_, :sigil_r, :sigil_R]



  alias Credo.Code.Block

  alias Credo.Code.Module



  use Credo.Check, base_priority: :high



  def run(source_file, params \\ []) do

    issue_meta = IssueMeta.for(source_file, params)



    Credo.Code.traverse(source_file, &traverse(&1, &2, issue_meta, @excluded_names))

    |> List.flatten

    |> Enum.reject(&is_nil/1)

  end



  defp traverse({:defmodule, _, _} = ast, issues, issue_meta, excluded_names) do

    def_names = Module.def_names_with_op(ast)

    issues =

      issues ++ Credo.Code.traverse(ast, &mod_traverse(&1, &2, issue_meta, def_names, excluded_names))

    {ast, issues}

  end

  defp traverse(ast, issues, _issue_meta, _excluded_names) do

    {ast, issues}

  end



  defp mod_traverse({:case, _meta, [_condition, _rhs]} = ast, issues, issue_meta, def_names, excluded_names) do

    block = Block.do_block_for!(ast)

    case issue_for(block, issue_meta, def_names, excluded_names) do

      nil -> {ast, issues}

      list when is_list(list) -> {ast, issues ++ list}

      new_issue -> {ast, issues ++ [new_issue]}

    end

  end

  defp mod_traverse(ast, issues, _issue_meta, _def_names, _excluded_names) do

    {ast, issues}

  end







  def issue_for({:->, _meta2, [lhs, _rhs]}, issue_meta, def_names, excluded_names) do

    issue_for(lhs, issue_meta, def_names, excluded_names)

  end

  def issue_for({:%{}, _meta2, keywords}, issue_meta, def_names, excluded_names) do

    keywords

    |> Enum.map(fn

      {_lhs, rhs} ->

        issue_for(rhs, issue_meta, def_names, excluded_names)

      _ ->

        nil

      end)

  end

  def issue_for({:{}, _meta2, tuple_list}, issue_meta, def_names, excluded_names) do

    issue_for(tuple_list, issue_meta, def_names, excluded_names)

  end

  def issue_for({:%, _meta, [{:__aliases__, _meta1, _mod}, map]}, issue_meta, def_names, excluded_names) do

    issue_for(map, issue_meta, def_names, excluded_names)

  end

  def issue_for({name, meta, _}, issue_meta, def_names, excluded_names) do

    def_name_with_op =

      def_names

      |> Enum.find(fn({def_name, _op}) -> def_name == name end)

    cond do

      excluded_names |> Enum.member?(name) ->

        nil

      def_name_with_op ->

        what =

          case def_name_with_op do

            {_, :def} -> "a function in the same module"

            {_, :defp} -> "a private function in the same module"

            {_, :defmacro} -> "a macro in the same module"

            _ -> "ERROR"

          end

        create_issue(meta[:line], name, what, issue_meta)

      @kernel_fun_names |> Enum.member?(name) ->

        create_issue(meta[:line], name, "the `Kernel.#{name}` function", issue_meta)

      @kernel_macro_names |> Enum.member?(name) ->

        create_issue(meta[:line], name, "the `Kernel.#{name}` macro", issue_meta)

      true ->

        nil

    end

  end

  def issue_for(list, issue_meta, def_names, excluded_names) when is_list(list) do

    list

    |> Enum.map(&issue_for(&1, issue_meta, def_names, excluded_names))

  end

  def issue_for(tuple, issue_meta, def_names, excluded_names) when is_tuple(tuple) do

    tuple

    |> Tuple.to_list

    |> Enum.map(&issue_for(&1, issue_meta, def_names, excluded_names))

  end

  def issue_for(_, _, _, _) do

    nil

  end



  defp create_issue(line_no, trigger, what, issue_meta) do

    format_issue issue_meta,

      message: "Variable `#{trigger}` has same name as #{what}.",

      trigger: trigger,

      line_no: line_no

  end

end