corex

defmodule Corex.Carousel.Connect do
  @moduledoc false
  alias Corex.Carousel.Anatomy.{
    Control,
    Indicator,
    IndicatorGroup,
    Item,
    ItemGroup,
    NextTrigger,
    PrevTrigger,
    Props,
    Root
  }

  alias Corex.Selectors
  alias Phoenix.LiveView.JS
  import Corex.Helpers, only: [get_boolean: 1, maybe_put_data_dir: 2, maybe_put_dir: 2]

  defp slides_per_move_value(nil), do: nil
  defp slides_per_move_value("auto"), do: "auto"
  defp slides_per_move_value(:auto), do: "auto"
  defp slides_per_move_value(n) when is_integer(n), do: to_string(n)
  defp slides_per_move_value(n) when is_binary(n), do: n

  @spec props(Props.t()) :: map()
  def props(assigns) do
    base = %{
      "id" => assigns.id,
      "data-slide-count" => to_string(assigns.slide_count),
      "data-page" => if(assigns.controlled, do: to_string(assigns.page), else: nil),
      "data-default-page" => if(assigns.controlled, do: nil, else: to_string(assigns.page)),
      "data-controlled" => get_boolean(assigns.controlled),
      "data-orientation" => assigns.orientation,
      "data-slides-per-page" => to_string(assigns.slides_per_page),
      "data-loop" => get_boolean(assigns.loop),
      "data-autoplay" => get_boolean(assigns.autoplay),
      "data-autoplay-delay" =>
        if(assigns.autoplay, do: to_string(assigns.autoplay_delay), else: nil),
      "data-allow-mouse-drag" => get_boolean(assigns.allow_mouse_drag),
      "data-spacing" => assigns.spacing,
      "data-in-view-threshold" => to_string(assigns.in_view_threshold),
      "data-snap-type" => assigns.snap_type,
      "data-auto-size" => get_boolean(assigns.auto_size),
      "data-on-page-change" => assigns.on_page_change,
      "data-on-page-change-client" => assigns.on_page_change_client
    }

    base
    |> maybe_put_data_dir(assigns.dir)
    |> maybe_put_string("data-slides-per-move", slides_per_move_value(assigns.slides_per_move))
    |> maybe_put_string("data-padding", assigns.padding)
  end

  defp maybe_put_string(map, _key, nil), do: map
  defp maybe_put_string(map, key, value), do: Map.put(map, key, to_string(value))

  @spec root(Root.t()) :: map()
  def root(assigns) do
    slides_per_page = assigns.slides_per_page || 1
    spacing = assigns.spacing || "0px"

    slide_item_size =
      "calc(100% / var(--slides-per-page) - var(--slide-spacing) * (var(--slides-per-page) - 1) / var(--slides-per-page))"

    style =
      "width:100%;overflow:hidden;--slides-per-page:#{slides_per_page};--slide-spacing:#{spacing};--slide-item-size:#{slide_item_size};aspect-ratio:4/3"

    base =
      %{
        "data-scope" => "carousel",
        "data-part" => "root",
        "data-orientation" => assigns.orientation || "horizontal",
        "id" => "carousel:#{assigns.id}",
        "style" => style
      }
      |> maybe_put_dir(assigns.dir)

    case Map.get(assigns, :aria_label) do
      nil -> Map.put(base, "aria-label", "Carousel #{assigns.id}")
      label -> Map.put(base, "aria-label", label)
    end
  end

  def ignore_root(%Root{} = assigns) do
    JS.ignore_attributes(Root.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}")
    )
  end

  @spec control(Control.t()) :: map()
  def control(assigns) do
    %{
      "data-scope" => "carousel",
      "data-part" => "control",
      "data-orientation" => assigns.orientation || "horizontal",
      "id" => "carousel:#{assigns.id}:control"
    }
  end

  def ignore_control(%Control{} = assigns) do
    JS.ignore_attributes(Control.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:control")
    )
  end

  @spec item_group(ItemGroup.t()) :: map()
  def item_group(assigns) do
    horizontal = (assigns.orientation || "horizontal") == "horizontal"

    style =
      if horizontal do
        "min-width:0;display:grid;gap:var(--slide-spacing);scroll-snap-type:x mandatory;grid-auto-flow:column;scrollbar-width:none;overscroll-behavior-x:contain;grid-auto-columns:var(--slide-item-size);overflow-x:auto"
      else
        "min-height:0;display:grid;gap:var(--slide-spacing);scroll-snap-type:y mandatory;grid-auto-flow:row;scrollbar-width:none;overscroll-behavior-y:contain;grid-auto-rows:var(--slide-item-size);overflow-y:auto"
      end

    %{
      "data-scope" => "carousel",
      "data-part" => "item-group",
      "data-orientation" => assigns.orientation || "horizontal",
      "id" => "carousel:#{assigns.id}:item-group",
      "aria-live" => "polite",
      "style" => style,
      "tabindex" => "0"
    }
    |> maybe_put_dir(assigns.dir)
  end

  def ignore_item_group(%ItemGroup{} = assigns) do
    JS.ignore_attributes(ItemGroup.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:item-group")
    )
  end

  @spec item(Item.t()) :: map()
  def item(assigns) do
    horizontal = (assigns.orientation || "horizontal") == "horizontal"
    size_style = if horizontal, do: "max-width:100%", else: "max-height:100%"
    slide_count = assigns.slide_count || 1

    style = "flex:0 0 auto;#{size_style};scroll-snap-align:start"

    %{
      "data-scope" => "carousel",
      "data-part" => "item",
      "data-index" => to_string(assigns.index),
      "data-orientation" => assigns.orientation || "horizontal",
      "id" => "carousel:#{assigns.id}:item:#{assigns.index}",
      "role" => "group",
      "aria-roledescription" => "slide",
      "aria-label" => "#{assigns.index + 1} of #{slide_count}",
      "style" => style
    }
    |> maybe_put_dir(Map.get(assigns, :dir))
  end

  def ignore_item(%Item{} = assigns) do
    JS.ignore_attributes(Item.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:item:#{assigns.index}")
    )
  end

  @spec prev_trigger(PrevTrigger.t()) :: map()
  def prev_trigger(assigns) do
    base = %{
      "data-scope" => "carousel",
      "data-part" => "prev-trigger",
      "type" => "button",
      "aria-label" => "Previous slide",
      "id" => "carousel:#{assigns.id}:prev"
    }

    if Map.get(assigns, :disabled, false) do
      Map.put(base, "disabled", "")
    else
      base
    end
  end

  def ignore_prev_trigger(%PrevTrigger{} = assigns) do
    JS.ignore_attributes(PrevTrigger.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:prev")
    )
  end

  @spec next_trigger(NextTrigger.t()) :: map()
  def next_trigger(assigns) do
    base = %{
      "data-scope" => "carousel",
      "data-part" => "next-trigger",
      "type" => "button",
      "aria-label" => "Next slide",
      "id" => "carousel:#{assigns.id}:next"
    }

    if Map.get(assigns, :disabled, false) do
      Map.put(base, "disabled", "")
    else
      base
    end
  end

  def ignore_next_trigger(%NextTrigger{} = assigns) do
    JS.ignore_attributes(NextTrigger.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:next")
    )
  end

  @spec indicator_group(IndicatorGroup.t()) :: map()
  def indicator_group(assigns) do
    %{
      "data-scope" => "carousel",
      "data-part" => "indicator-group",
      "data-orientation" => assigns.orientation || "horizontal",
      "id" => "carousel:#{assigns.id}:indicator-group"
    }
    |> maybe_put_dir(assigns.dir)
  end

  def ignore_indicator_group(%IndicatorGroup{} = assigns) do
    JS.ignore_attributes(IndicatorGroup.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:indicator-group")
    )
  end

  @spec indicator(Indicator.t()) :: map()
  def indicator(assigns) do
    page = Map.get(assigns, :page, 0)

    %{
      "data-scope" => "carousel",
      "data-part" => "indicator",
      "data-index" => to_string(assigns.index),
      "data-current" => get_boolean(assigns.index == page),
      "data-orientation" => assigns.orientation || "horizontal",
      "type" => "button",
      "id" => "carousel:#{assigns.id}:indicator:#{assigns.index}"
    }
    |> maybe_put_dir(assigns.dir)
  end

  def ignore_indicator(%Indicator{} = assigns) do
    JS.ignore_attributes(Indicator.ignored_attrs(),
      to: Selectors.css_id("carousel:#{assigns.id}:indicator:#{assigns.index}")
    )
  end
end