Packages
commanded
0.18.0
1.4.10
1.4.9
1.4.8
1.4.7
1.4.6
1.4.3
1.4.2
1.4.1
1.4.0
1.4.0-rc.0
1.3.1
1.3.0
1.2.0
1.1.1
1.1.0
1.0.1
1.0.0
1.0.0-rc.1
1.0.0-rc.0
0.19.1
0.19.0
0.18.1
0.18.0
0.17.5
0.17.4
0.17.3
0.17.2
0.17.1
0.17.0
0.16.0
0.16.0-rc.1
0.16.0-rc.0
0.15.1
0.15.0
0.14.0
0.14.0-rc.0
0.13.0
0.12.0
0.11.0
0.10.0
0.9.0
0.8.5
0.8.4
0.8.3
0.8.1
0.8.0
0.7.1
0.6.2
0.6.1
0.6.0
0.4.0
0.3.1
0.3.0
0.2.1
0.2.0
0.1.0
Use Commanded to build your own Elixir applications following the CQRS/ES pattern.
Current section
Files
Jump to
Current section
Files
test/example_domain/money_transfer/transfer_money_process_manager.ex
defmodule Commanded.ExampleDomain.TransferMoneyProcessManager do
@moduledoc false
use Commanded.ProcessManagers.ProcessManager,
name: __MODULE__,
router: Commanded.ExampleDomain.BankRouter
@derive Jason.Encoder
defstruct [:transfer_uuid, :debit_account, :credit_account, :amount, :status]
alias Commanded.ExampleDomain.TransferMoneyProcessManager
alias Commanded.ExampleDomain.MoneyTransfer.Events.MoneyTransferRequested
alias Commanded.ExampleDomain.BankAccount.Events.MoneyDeposited
alias Commanded.ExampleDomain.BankAccount.Events.MoneyWithdrawn
alias Commanded.ExampleDomain.BankAccount.Commands.DepositMoney
alias Commanded.ExampleDomain.BankAccount.Commands.WithdrawMoney
def interested?(%MoneyTransferRequested{transfer_uuid: transfer_uuid}),
do: {:start, transfer_uuid}
def interested?(%MoneyWithdrawn{transfer_uuid: transfer_uuid}),
do: {:continue, transfer_uuid}
def interested?(%MoneyDeposited{transfer_uuid: transfer_uuid}),
do: {:continue, transfer_uuid}
def handle(%TransferMoneyProcessManager{}, %MoneyTransferRequested{} = event) do
%MoneyTransferRequested{
transfer_uuid: transfer_uuid,
debit_account: debit_account,
amount: amount
} = event
%WithdrawMoney{account_number: debit_account, transfer_uuid: transfer_uuid, amount: amount}
end
def handle(%TransferMoneyProcessManager{} = pm, %MoneyWithdrawn{}) do
%TransferMoneyProcessManager{
transfer_uuid: transfer_uuid,
credit_account: credit_account,
amount: amount
} = pm
%DepositMoney{account_number: credit_account, transfer_uuid: transfer_uuid, amount: amount}
end
## State mutators
def apply(%TransferMoneyProcessManager{} = transfer, %MoneyTransferRequested{} = event) do
%MoneyTransferRequested{
transfer_uuid: transfer_uuid,
debit_account: debit_account,
credit_account: credit_account,
amount: amount
} = event
%TransferMoneyProcessManager{
transfer
| transfer_uuid: transfer_uuid,
debit_account: debit_account,
credit_account: credit_account,
amount: amount,
status: :withdraw_money_from_debit_account
}
end
def apply(%TransferMoneyProcessManager{} = transfer, %MoneyWithdrawn{}) do
%TransferMoneyProcessManager{transfer | status: :deposit_money_in_credit_account}
end
def apply(%TransferMoneyProcessManager{} = transfer, %MoneyDeposited{}) do
%TransferMoneyProcessManager{transfer | status: :transfer_complete}
end
end