Packages

chromic_pdf

1.10.0
1.17.1 1.17.0 1.16.1 1.16.0 1.15.2 1.15.1 1.15.0 1.14.0 1.13.0 1.12.0 1.11.0 1.10.0 1.9.1 1.9.0 1.8.1 1.8.0 1.7.0 1.6.0 1.5.0 1.4.0 1.3.1 1.3.0 1.2.2 1.2.1 1.2.0 1.1.2 1.1.1 1.1.0 1.0.0 0.7.2 0.7.1 0.7.0 0.6.2 0.6.1 0.6.0 0.5.2 0.5.1 0.5.0 0.4.0 0.3.1 0.3.0 0.2.0 0.1.0

Fast HTML-2-PDF/A renderer based on Chrome & Ghostscript

HexDocs

Current section

Files

Jump to
Readme
43 Versions
3 Dependencies
Dependants
Files
Activity
chromic_pdf lib chromic_pdf pdf connection.ex
Raw

lib/chromic_pdf/pdf/connection.ex 

# SPDX-License-Identifier: Apache-2.0



defmodule ChromicPDF.Connection do

  @moduledoc false



  @type state :: map()

  @type msg :: binary()



  @callback start_link(keyword()) :: {:ok, pid()}

  @callback handle_init(keyword()) :: {:ok, state()}

  @callback handle_msg(msg(), state()) :: :ok



  @spec start_link(keyword()) :: GenServer.on_start()

  def start_link(opts) do

    strategy = Keyword.get(opts, :connection_strategy, ChromicPDF.Connection.Local)



    strategy.start_link(opts)

  end



  @spec send_msg(pid(), binary()) :: :ok

  def send_msg(pid, msg) do

    :ok = GenServer.cast(pid, {:msg, msg})

  end



  defmacro __using__(_) do

    quote do

      use GenServer

      alias ChromicPDF.Connection



      @behaviour Connection



      @impl Connection

      def start_link(opts) do

        GenServer.start_link(__MODULE__, {self(), opts})

      end



      @impl GenServer

      def init({channel_pid, opts}) do

        {:ok, state} = handle_init(opts)



        {:ok, Map.put(state, :channel_pid, channel_pid)}

      end



      @impl GenServer

      def handle_cast({:msg, msg}, state) do

        :ok = handle_msg(msg, state)



        {:noreply, state}

      end



      defp send_msg_to_channel(msg, %{channel_pid: channel_pid} = state) do

        send(channel_pid, {:msg, msg})

      end

    end

  end

end