Packages
brod
3.15.6
4.5.7
4.5.6
4.5.5
4.5.4
4.5.3
4.5.2
4.5.1
4.5.0
4.4.7
4.4.6
4.4.5
4.4.4
4.4.3
4.4.2
4.4.1
4.4.0
4.3.3
4.3.2
4.3.1
4.3.0
4.2.0
4.1.1
4.1.0
4.0.0
3.19.1
3.19.0
3.18.0
3.17.1
3.17.0
3.16.5
3.16.4
3.16.3
3.16.2
3.16.1
3.16.0
3.15.6
3.15.5
3.15.4
3.15.3
3.15.1
3.15.0
3.14.0
3.13.0
3.12.0
3.11.0
3.10.0
3.9.5
3.9.3
3.9.2
3.9.1
3.9.0
3.8.1
3.8.0
3.7.11
3.7.10
3.7.9
3.7.8
3.7.7
3.7.6
3.7.5
3.7.4
3.7.3
3.7.2
3.7.1
3.7.0
3.6.2
3.6.1
3.6.0
3.5.2
3.5.1
3.5.0
3.4.0
3.3.5
3.3.4
3.3.3
3.3.2
3.3.1
3.3.0
3.2.0
3.0.0
2.5.0
2.4.1
2.4.0
2.3.7
2.3.6
2.3.5
2.3.4
2.3.3
2.3.1
2.2.16
2.2.15
2.2.14
2.2.12
2.2.11
2.2.10
2.2.9
2.2.8
2.2.7
2.2.6
2.2.5
2.2.4
2.2.3
2.2.2
2.2.1
2.2.0
2.1.12
2.1.11
2.1.10
2.1.8
2.1.7
2.1.4
2.1.2
2.0.0
Apache Kafka Erlang client library
Current section
Files
Jump to
Current section
Files
src/brod_kafka_apis.erl
%%%
%%% Copyright (c) 2017-2021 Klarna Bank AB (publ)
%%%
%%% Licensed under the Apache License, Version 2.0 (the "License");
%%% you may not use this file except in compliance with the License.
%%% You may obtain a copy of the License at
%%%
%%% http://www.apache.org/licenses/LICENSE-2.0
%%%
%%% Unless required by applicable law or agreed to in writing, software
%%% distributed under the License is distributed on an "AS IS" BASIS,
%%% WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
%%% See the License for the specific language governing permissions and
%%% limitations under the License.
%%%
%% @private
%% Version ranges are cached per host and per connection pid in ets
-module(brod_kafka_apis).
-export([ default_version/1
, pick_version/2
, start_link/0
, stop/0
]).
-export([ code_change/3
, handle_call/3
, handle_cast/2
, handle_info/2
, init/1
, terminate/2
]).
-include("brod_int.hrl").
-export_type([ api/0
, vsn/0
]).
-define(SERVER, ?MODULE).
-define(ETS, ?MODULE).
-record(state, {}).
-type vsn() :: kpro:vsn().
-type range() :: {vsn(), vsn()}.
-type api() :: kpro:api().
-type conn() :: kpro:connection().
%% @doc Start process.
-spec start_link() -> {ok, pid()}.
start_link() ->
gen_server:start_link({local, ?SERVER}, ?MODULE, [], []).
-spec stop() -> ok.
stop() ->
gen_server:call(?SERVER, stop, infinity).
%% @doc Get default supported version for the given API.
-spec default_version(api()) -> vsn().
default_version(API) ->
{Min, _Max} = supported_versions(API),
Min.
%% @doc Pick API version for the given API.
-spec pick_version(conn(), api()) -> vsn().
pick_version(Conn, API) ->
do_pick_version(Conn, API, supported_versions(API)).
%%%_* gen_server callbacks =====================================================
init([]) ->
?ETS = ets:new(?ETS, [named_table, public]),
{ok, #state{}}.
handle_info({'DOWN', _Mref, process, Conn, _Reason}, State) ->
_ = ets:delete(?ETS, Conn),
{noreply, State};
handle_info(Info, State) ->
?BROD_LOG_ERROR("unknown info ~p", [Info]),
{noreply, State}.
handle_cast({monitor_connection, Conn}, State) ->
erlang:monitor(process, Conn),
{noreply, State};
handle_cast(Cast, State) ->
?BROD_LOG_ERROR("unknown cast ~p", [Cast]),
{noreply, State}.
handle_call(stop, From, State) ->
gen_server:reply(From, ok),
{stop, normal, State};
handle_call(Call, _From, State) ->
{reply, {error, {unknown_call, Call}}, State}.
code_change(_OldVsn, State, _Extra) ->
{ok, State}.
terminate(_Reason, _State) ->
ok.
%%%_* Internals ================================================================
-spec do_pick_version(conn(), api(), range()) -> vsn().
do_pick_version(_Conn, _API, {V, V}) -> V;
do_pick_version(Conn, API, {Min, Max} = MyRange) ->
case lookup_vsn_range(Conn, API) of
none ->
Min; %% no version received from kafka, use min
{KproMin, KproMax} = Range when KproMin > Max orelse KproMax < Min ->
erlang:error({unsupported_vsn_range, API, MyRange, Range});
{_, KproMax} ->
min(KproMax, Max) %% try to use highest version
end.
%% Lookup API from cache, return 'none' if not found.
-dialyzer([{nowarn_function, [lookup_vsn_range/2]}]).
-spec lookup_vsn_range(conn(), api()) -> {vsn(), vsn()} | none.
lookup_vsn_range(Conn, API) ->
case ets:lookup(?ETS, Conn) of
[] ->
case kpro:get_api_versions(Conn) of
{ok, Versions} when is_map(Versions) ->
%% public ets, insert it by caller
ets:insert(?ETS, {Conn, Versions}),
%% tell ?SERVER to monitor the connection
%% so to delete it from cache when 'DOWN' is received
ok = monitor_connection(Conn),
maps:get(API, Versions, none);
{error, _Reason} ->
none %% connection died, ignore
end;
[{Conn, Vsns}] ->
maps:get(API, Vsns, none)
end.
%% Do not change range without verification.
supported_versions(API) ->
case API of
produce -> {0, 5};
fetch -> {0, 7};
list_offsets -> {0, 2};
metadata -> {0, 2};
offset_commit -> {2, 2};
offset_fetch -> {1, 2};
find_coordinator -> {0, 0};
join_group -> {0, 0};
heartbeat -> {0, 0};
leave_group -> {0, 0};
sync_group -> {0, 0};
describe_groups -> {0, 0};
list_groups -> {0, 0};
create_topics -> {0, 0};
delete_topics -> {0, 0};
_ -> erlang:error({unsupported_api, API})
end.
monitor_connection(Conn) ->
gen_server:cast(?SERVER, {monitor_connection, Conn}).
%%%_* Emacs ====================================================================
%%% Local Variables:
%%% allout-layout: t
%%% erlang-indent-level: 2
%%% End: