Packages

bitgraph

0.2.9
0.4.8 0.4.7 0.4.6 0.4.5 0.4.4 0.4.3 0.4.2 0.4.1 0.3.4 0.3.3 0.3.2 0.3.1 0.2.9 0.2.8 0.2.7 0.2.6 0.2.5 0.2.4 0.2.3 0.2.2 0.2.1 0.1.23 0.1.22 0.1.21 0.1.20 0.1.19 0.1.18 0.1.17 0.1.16 0.1.15 0.1.14 0.1.13 0.1.12 0.1.11 0.1.10 0.1.9 0.1.8 0.1.7 0.1.6 0.1.5 0.1.4 0.1.3 0.1.2 0.1.1 0.1.0

Mutable directed graph

HexDocs

Current section

Files

Jump to
Readme
45 Versions
3 Dependencies
Dependants
Files
Activity
bitgraph src bit_vector.erl
Raw

src/bit_vector.erl 

-module(bit_vector).



-export([new/1, get/2, set/2, clear/2, flip/2, print/1]).





% Allocate atomics to contain the data + 2 bytes for min and max

new(Size) ->

    Words = (Size + 63) div 64,

    Atomics = atomics:new(Words + 1, [{signed, false}]),

    atomics:put(Atomics, Words + 1, 0), %% Set 'min_max' to lowest possible

    {?MODULE, Atomics}.



    



get({?MODULE, Aref}, Bix) ->

    Wix = (Bix div 64) + 1,

    Mask = (1 bsl (Bix rem 64)),    

    case atomics:get(Aref, Wix) band Mask of

        0 -> 0;

        Mask -> 1

    end.



set({?MODULE, Aref}, Bix) ->

    Mask = (1 bsl (Bix rem 64)),    

    update(Aref, Bix, fun(Word) -> Word bor Mask end).



clear({?MODULE, Aref}, Bix) ->

    Mask = bnot (1 bsl (Bix rem 64)),

    update(Aref, Bix, fun(Word) -> Word band Mask end).



flip({?MODULE, Aref}, Bix) ->

    Mask = (1 bsl (Bix rem 64)),

    update(Aref, Bix, fun(Word) -> Word bxor Mask end).



print({?MODULE, Aref} = BV) ->

    #{size := Size} = atomics:info(Aref),

    print(BV, Size).

print(BV, 0) ->

    io:format("~B~n",[get(BV, 0)]);

print(BV, Slot) ->

    io:format("~B",[get(BV, Slot)]),

    print(BV, Slot-1).



update(Aref, Bix, Fun) ->

    Wix = (Bix div 64) + 1,

    update_loop(Aref, Wix, Fun, atomics:get(Aref, Wix)).



update_loop(Aref, Wix, Fun, Current) ->

    case atomics:compare_exchange(Aref, Wix, Current, Fun(Current)) of

       ok ->

           ok;

       Was ->

           update_loop(Aref, Wix, Fun, Was)

    end.