bingex

defmodule Bingex.Swap.Data.GetQuotes do
  @moduledoc """
  Represents response content on `Bingex.Swap.get_quotes` request.
  """

  alias Bingex.API.Reply
  alias Bingex.Swap.Model.QuoteInfo

  defstruct quotes: []

  @type t() :: %__MODULE__{
          quotes: [QuoteInfo.t()]
        }

  @spec embed_in_reply(Reply.t()) :: Reply.t(t())
  def embed_in_reply(%Reply{payload: payload} = reply) do
    Reply.put_data(reply, decode(payload))
  end

  @spec decode(any()) :: t()
  def decode(%{"data" => %{} = raw_quote}) do
    case QuoteInfo.decode(raw_quote) do
      {:ok, quote} -> %__MODULE__{quotes: [quote]}
      :error -> %__MODULE__{}
    end
  end

  def decode(%{"data" => data_list}) when is_list(data_list) do
    quotes =
      Enum.reduce(data_list, [], fn data, list ->
        case QuoteInfo.decode(data) do
          {:ok, struct} -> [struct | list]
          :error -> list
        end
      end)

    %__MODULE__{quotes: quotes}
  end

  def decode(_data), do: %__MODULE__{}
end